Re: gtk-doc version and configure.in breakage

[Owen Taylor <otaylor redhat com>]

After some further discussion with Dan, what I ended up using
for Pango was:

#
# Check for sufficiently new gtk-doc
#
gtk_doc_min_version=0.10

AC_CHECK_PROG(GTKDOC, gtkdoc-mkdb, true, false)
if $GTKDOC ; then
    gtk_doc_version=`gtkdoc-mkdb --version`
    AC_MSG_CHECKING([gtk-doc version ($gtk_doc_version) >= $gtk_doc_min_version\])

    IFS="${IFS=         }"; pango_save_IFS="$IFS"; IFS="."
    set $gtk_doc_version
    for min in $gtk_doc_min_version ; do
        cur=$1; shift
        if test -z $min ; then break; fi
        if test -z $cur ; then GTKDOC=false; break; fi
        if test $cur -gt $min ; then break ; fi
        if test $cur -lt $min ; then GTKDOC=false; break ; fi
    done
    IFS="$pango_save_IFS"

    if $GTKDOC ; then
      AC_MSG_RESULT(yes)
    else
      AC_MSG_RESULT(no)
    fi
fi

I suspect we should do one of the following:

 A) Install a gtk-doc.m4 with a AM_PATH_GTK_DOC($min_version)
 B) Install a gtk-doc.pc file so people can use 
    $PKG_CONFIG --exists gtk-doc >= 0.10

Probably the former makes more sense; it could do some of the
boiler-plate that gets cut-and-pasted around too.

Regards,
                                        Owen