[gnome-bluetooth] Add non-working Introspection support

[Bastien Nocera <hadess src gnome org>]

commit 53f5edc35f47311888b7bdead8b05eb8837ef62e
Author: Bastien Nocera <hadess hadess net>
Date:   Fri Jun 26 01:05:06 2009 +0100

    Add non-working Introspection support

 acinclude.m4                |   88 +++++++++++++++++++++++++++++++++++++++++++
 configure.ac                |    2 +
 lib/Makefile.am             |   42 ++++++++++++++++++++-
 lib/gnome-bluetooth.symbols |    3 +
 4 files changed, 134 insertions(+), 1 deletions(-)
---
diff --git a/acinclude.m4 b/acinclude.m4
new file mode 100644
index 0000000..bb3a0da
--- /dev/null
+++ b/acinclude.m4
@@ -0,0 +1,88 @@
+dnl -*- mode: autoconf -*-
+dnl Copyright 2009 Johan Dahlin
+dnl
+dnl This file is free software; the author(s) gives unlimited
+dnl permission to copy and/or distribute it, with or without
+dnl modifications, as long as this notice is preserved.
+dnl
+
+# serial 1
+
+m4_define([_GOBJECT_INTROSPECTION_CHECK_INTERNAL],
+[
+    AC_BEFORE([AC_PROG_LIBTOOL],[$0])dnl setup libtool first
+    AC_BEFORE([AM_PROG_LIBTOOL],[$0])dnl setup libtool first
+    AC_BEFORE([LT_INIT],[$0])dnl setup libtool first
+
+    dnl enable/disable introspection
+    m4_if([$2], [require],
+    [dnl
+        enable_introspection=yes
+    ],[dnl
+        AC_ARG_ENABLE(introspection,
+                  AS_HELP_STRING([--enable-introspection[=@<:@no/auto/yes@:>@]],
+                                 [Enable introspection for this build]),,
+                                 [enable_introspection=auto])
+    ])dnl
+
+    AC_MSG_CHECKING([for gobject-introspection])
+
+    dnl presence/version checking
+    AS_CASE([$enable_introspection],
+    [no], [dnl
+        found_introspection="no (disabled, use --enable-introspection to enable)"
+    ],dnl
+    [yes],[dnl
+        PKG_CHECK_EXISTS([gobject-introspection-1.0],,
+                         AC_MSG_ERROR([gobject-introspection-1.0 is not installed]))
+        PKG_CHECK_EXISTS([gobject-introspection-1.0 >= $1],
+                         found_introspection=yes,
+                         AC_MSG_ERROR([You need to have gobject-introspection >= $1 installed to build AC_PACKAGE_NAME]))
+    ],dnl
+    [auto],[dnl
+        PKG_CHECK_EXISTS([gobject-introspection-1.0 >= $1], found_introspection=yes, found_introspection=no)
+    ],dnl
+    [dnl
+        AC_MSG_ERROR([invalid argument passed to --enable-introspection, should be one of @<:@no/auto/yes@:>@])
+    ])dnl
+
+    AC_MSG_RESULT([$found_introspection])
+
+    INTROSPECTION_SCANNER=
+    INTROSPECTION_COMPILER=
+    INTROSPECTION_GENERATE=
+    INTROSPECTION_GIRDIR=
+    INTROSPECTION_TYPELIBDIR=
+    if test "x$found_introspection" = "xyes"; then
+       INTROSPECTION_SCANNER=`$PKG_CONFIG --variable=g_ir_scanner gobject-introspection-1.0`
+       INTROSPECTION_COMPILER=`$PKG_CONFIG --variable=g_ir_compiler gobject-introspection-1.0`
+       INTROSPECTION_GENERATE=`$PKG_CONFIG --variable=g_ir_generate gobject-introspection-1.0`
+       INTROSPECTION_GIRDIR=`$PKG_CONFIG --variable=girdir gobject-introspection-1.0`
+       INTROSPECTION_TYPELIBDIR="$($PKG_CONFIG --variable=typelibdir gobject-introspection-1.0)"
+    fi
+    AC_SUBST(INTROSPECTION_SCANNER)
+    AC_SUBST(INTROSPECTION_COMPILER)
+    AC_SUBST(INTROSPECTION_GENERATE)
+    AC_SUBST(INTROSPECTION_GIRDIR)
+    AC_SUBST(INTROSPECTION_TYPELIBDIR)
+
+    AM_CONDITIONAL(HAVE_INTROSPECTION, test "x$found_introspection" = "xyes")
+])
+
+
+dnl Usage:
+dnl   GOBJECT_INTROSPECTION_CHECK([minimum-g-i-version])
+
+AC_DEFUN([GOBJECT_INTROSPECTION_CHECK],
+[
+  _GOBJECT_INTROSPECTION_CHECK_INTERNAL([$1])
+])
+
+dnl Usage:
+dnl   GOBJECT_INTROSPECTION_REQUIRE([minimum-g-i-version])
+
+
+AC_DEFUN([GOBJECT_INTROSPECTION_REQUIRE],
+[
+  _GOBJECT_INTROSPECTION_CHECK_INTERNAL([$1], [require])
+])
diff --git a/configure.ac b/configure.ac
index 30a332b..f997a7d 100644
--- a/configure.ac
+++ b/configure.ac
@@ -125,6 +125,8 @@ AC_SUBST(DBUS_BINDING_TOOL)
 GLIB_GENMARSHAL=`$PKG_CONFIG --variable=glib_genmarshal glib-2.0`
 AC_SUBST(GLIB_GENMARSHAL)
 
+GOBJECT_INTROSPECTION_CHECK([0.6.3])
+
 GNOME_COMMON_INIT
 GNOME_DEBUG_CHECK
 GNOME_COMPILE_WARNINGS([maximum])
diff --git a/lib/Makefile.am b/lib/Makefile.am
index 28b17b4..82b8e8f 100644
--- a/lib/Makefile.am
+++ b/lib/Makefile.am
@@ -1,5 +1,8 @@
 SUBDIRS = plugins
 
+EXTRA_DIST = 
+BUILT_GIRSOURCES =
+
 noinst_LTLIBRARIES = libcommon.la
 lib_LTLIBRARIES = libgnome-bluetooth.la
 
@@ -44,6 +47,43 @@ gnomebluetooth_HEADERS =				\
 
 AM_CFLAGS = -I$(srcdir) $(LIBGNOMEBT_CFLAGS) $(COMMON_CFLAGS) $(WARN_CFLAGS) $(DISABLE_DEPRECATED) -DPLUGINDIR=\"$(libdir)/gnome-bluetooth/plugins\"
 
+BUILT_GIRSOURCES += GnomeBluetooth-2.0.gir
+
+GnomeBluetooth-2.0.gir: $(libgnome_bluetooth_la_SOURCES)
+GnomeBluetooth-2.0.gir: $(gnomebluetooth_HEADERS)
+GnomeBluetooth-2.0.gir: libgnome-bluetooth.la
+GnomeBluetooth-2.0.gir: $(INTROSPECTION_SCANNER)
+	$(INTROSPECTION_SCANNER) -v --namespace GnomeBluetooth --nsversion=2.0 \
+		--add-include-path=$(srcdir) --add-include-path=. \
+		--include=GObject-2.0 \
+		--include=Gtk-2.0 \
+		--include=DBus-1.0 \
+		--libtool="$(LIBTOOL)" \
+		--library=gnome-bluetooth \
+		--output $@ \
+		--pkg gobject-2.0 \
+		--pkg gtk+-2.0 \
+		--pkg dbus-glib-1 \
+		-I$(top_srcdir) \
+		$(LIBGNOMEBT_CFLAGS) \
+		$(libgnome_bluetooth_la_SOURCES) \
+		$(gnomebluetooth_HEADERS)
+
+if HAVE_INTROSPECTION
+
+girdir = $(GIRDIR)
+dist_gir_DATA = $(BUILT_GIRSOURCES)
+
+EXTRA_DIST += $(BUILT_GIRSOURCES)
+
+typelibsdir = $(TYPELIBDIR)
+typelibs_DATA = $(BUILT_GIRSOURCES:.gir=.typelib)
+
+%.typelib: %.gir $(G_IR_COMPILER)
+	LD_LIBRARY_PATH=$${LD_LIBRARY_PATH:+$$LD_LIBRARY_PATH:}. $(INTROSPECTION_COMPILER) --includedir=$(srcdir) --includedir=. $(G_IR_COMPILER_OPTS) $< -o $(builddir)/$(@F)
+	
+endif # HAVE_INTROSPECTION
+
 BUILT_SOURCES = marshal.h marshal.c \
 		bluetooth-client-glue.h \
 		bluetooth-agent-glue.h \
@@ -65,7 +105,7 @@ test_deviceselection_LDADD = libgnome-bluetooth.la
 
 test_plugins_LDADD = libcommon.la
 
-EXTRA_DIST = marshal.list \
+EXTRA_DIST += marshal.list \
 		bluetooth-client.xml \
 		bluetooth-agent.xml \
 		obex-agent.xml \
diff --git a/lib/gnome-bluetooth.symbols b/lib/gnome-bluetooth.symbols
index 8a3665f..662a03d 100644
--- a/lib/gnome-bluetooth.symbols
+++ b/lib/gnome-bluetooth.symbols
@@ -15,3 +15,6 @@ bluetooth_chooser_button_available
 bluetooth_client_get_type
 bling_spinner_get_type
 bluetooth_type_to_string
+bluetooth_column_get_type
+bluetooth_category_get_type
+bluetooth_type_get_type