Re: Compiling gnome-core-1.1.9 -gtkhtml

[Jacob Berkman <jacob helixcode com>]

mike <mike@redtux.demon.co.uk> writes:

> Durng config I get a message saying that a recent enough version of
> gtkhtnl s not installed
> 
> I installed the latest cvs version  this afternon (I had to install
>  gdk-pixbuf-0.7.0 to do it so I know) AND I CHECKED
> 
> Can someone please tell me which version to get!

from gnome-core/configure.in:

[ snip ]

AC_ARG_WITH(gtkhtml,
[  --with-gtkhtml=PREFIX  Specify gtkhtml prefix],[
    GTK_HTML_PREFIX="$with_gtkhtml"], [
    GTK_HTML_PREFIX=`$GNOME_CONFIG --prefix`])
AC_SUBST(GTK_HTML_PREFIX)

dnl help-browser using gtkhtml
AC_ARG_WITH(gnome-print,
[  --with-gnome-print=PREFIX  Specify gnome-print prefix],[
    GNOME_PRINT_PREFIX="$with_gnome_print"], [
    GNOME_PRINT_PREFIX=`$GNOME_CONFIG --prefix`])
AC_SUBST(GNOME_PRINT_PREFIX)

help_use_gtkhtml=false

CPPFLAGS_save=$CPPFLAGS
LDFLAGS_save=$LDFLAGS
CPPFLAGS=`$GNOME_CONFIG --cflags gtkhtml`
LDFLAGS=`$GNOME_CONFIG --libs gtkhtml`

lib_gtkhtml=false
AC_CHECK_LIB(gtkhtml, gtk_html_construct, lib_gtkhtml=true, [
        AC_MSG_WARN([Recent enough GtkHTML library not found (using GtkXmHTML)
        ])
])

CPPFLAGS=$CPPFLAGS_save
LDFLAGS=$LDFLAGS_save

dnl this shouldn't be enabled by default yet, since gtkhtml has some bugs
AC_ARG_ENABLE(gtkhtml-help, [  --enable-gtkhtml-help  Use GtkHTML for the help browser],
        gtkhtml_enabled="$enableval", gtkhtml_enabled=no)

if test "x$gtkhtml_enabled" = "xyes" ; then
        if test "x$lib_gtkhtml" = "xtrue" ; then
                AC_MSG_CHECKING(for static libgtkhtml)
                if test -e $GTK_HTML_PREFIX/lib/libgtkhtml.a ; then
                        AC_MSG_RESULT(yes)
                        AC_MSG_CHECKING(for static libgnomeprint)
                        if test -e $GNOME_PRINT_PREFIX/lib/libgnomeprint.a ; then
                                AC_MSG_RESULT(yes)
                                help_use_gtkhtml=true
                        else
                                AC_MSG_RESULT(no)
                        fi
                else
                        AC_MSG_RESULT(no)
                fi
        fi
fi

AC_MSG_CHECKING(which HTML widget to use)
if test "x$help_use_gtkhtml" = "xtrue" ; then
        AC_MSG_RESULT(GtkHTML)
else
        AC_MSG_RESULT(GtkXmHTML)
fi

AM_CONDITIONAL(HELP_USE_GTKHTML, test x$help_use_gtkhtml = xtrue)
dnl AC_SUBST(HELP_USE_GTKHTML)

[ snip ]

HTH,
Jacob
-- 
"Is this love... or just confusion?"  -- Jimi Hendrix