[nautilus-python/wip/jtojnar/ci: 1/2] Add files for Nix development environment

[Jan Tojnar <jtojnar src gnome org>]

commit 508e3ae3417385ae655fe59e93c384c44e7fb029
Author: Jan Tojnar <jtojnar gmail com>
Date:   Tue Sep 6 11:14:03 2022 +0200

    Add files for Nix development environment
    
    Nix [1] is purely functional package manager allowing to easily
    install dependencies in a reproducible manner.
    A developer can run `nix-shell` in the project directory
    and they will be dropped into a shell with all the necessary
    build dependencies.
    
    The dependencies are pinned so that same version can be
    used on CI and developers’ machines.
    One can run `nix-shell --run 'niv update'` to update to latest version.
    
    [1]: https://nixos.org/

 default.nix      | 105 ++++++++++++++++++++++++++++++
 nix/sources.json |  26 ++++++++
 nix/sources.nix  | 194 +++++++++++++++++++++++++++++++++++++++++++++++++++++++
 shell.nix        |   8 +++
 4 files changed, 333 insertions(+)
---
diff --git a/default.nix b/default.nix
new file mode 100644
index 0000000..709b27d
--- /dev/null
+++ b/default.nix
@@ -0,0 +1,105 @@
+/*
+
+How to use?
+***********
+
+If you have Nix installed, you can get an environment with everything
+needed to compile nautilus-python by running:
+
+    $ nix-shell
+
+at the root of the nautilus-python repository.
+
+You can also compile nautilus-python and ‘install’ it by running:
+
+    $ nix-build
+
+at the root of the nautilus-python repository. The command will install
+nautilus-python to a location under Nix store and create a ‘result’ symlink
+in the current directory pointing to the in-store location.
+
+The dependencies are pinned, you can update them to latest versions with:
+
+    $ nix-shell --run 'niv update'
+
+How to tweak default arguments?
+*******************************
+
+Nix supports the ‘--arg’ option (see nix-build(1)) that allows you
+to override the top-level arguments.
+
+For instance, to use your local copy of Nixpkgs:
+
+    $ nix-build --arg pkgs "import $HOME/Projects/nixpkgs {}"
+
+Or to speed up the build by not running the test suite:
+
+    $ nix-build --arg doCheck false
+
+*/
+
+{
+  # Nixpkgs instance, will default to one from Niv.
+  pkgs ? null,
+  # Whether to run tests when building File Roller using nix-build.
+  doCheck ? true,
+  # Whether to build File Roller, or shell for developing it.
+  # We do not use lib.inNixShell because that would also apply
+  # when in a nix-shell of some package depending on this one.
+  shell ? false,
+} @ args:
+
+let
+  # Pinned Nix dependencies (e.g. Nixpkgs) managed by Niv.
+  sources = import ./nix/sources.nix;
+
+  # Setting pkgs to the pinned version
+  # when not overridden in args.
+  pkgs =
+    if args.pkgs or null == null
+    then
+      import sources.nixpkgs {
+        overlays = [];
+        config = {};
+      }
+    else args.pkgs;
+
+  inherit (pkgs) lib;
+
+  # Function for building File Roller or shell for developing it.
+  makeDerivation =
+    if shell
+    then pkgs.mkShell
+    else pkgs.stdenv.mkDerivation;
+in
+makeDerivation rec {
+  name = "nautilus-python";
+
+  src =
+    let
+      # Do not copy to the store paths listed in .gitignore files
+      cleanSource = path: pkgs.nix-gitignore.gitignoreFilterRecursiveSource (_: _: true) [ ] path;
+    in
+    if shell then null else cleanSource ./.;
+
+  # Dependencies for build platform
+  nativeBuildInputs = with pkgs; ([
+    pkg-config
+    meson
+    ninja
+    gtk-doc
+    docbook-xsl-nons
+    docbook_xml_dtd_412
+  ] ++ lib.optionals shell [
+    niv
+  ]);
+
+  # Dependencies for host platform
+  buildInputs = with pkgs; [
+    python3
+    python3.pkgs.pygobject3
+    gnome.nautilus
+  ];
+
+  inherit doCheck;
+}
diff --git a/nix/sources.json b/nix/sources.json
new file mode 100644
index 0000000..86bde87
--- /dev/null
+++ b/nix/sources.json
@@ -0,0 +1,26 @@
+{
+    "niv": {
+        "branch": "master",
+        "description": "Easy dependency management for Nix projects",
+        "homepage": "https://github.com/nmattia/niv";,
+        "owner": "nmattia",
+        "repo": "niv",
+        "rev": "82e5cd1ad3c387863f0545d7591512e76ab0fc41",
+        "sha256": "090l219mzc0gi33i3psgph6s2pwsc8qy4lyrqjdj4qzkvmaj65a7",
+        "type": "tarball",
+        "url": "https://github.com/nmattia/niv/archive/82e5cd1ad3c387863f0545d7591512e76ab0fc41.tar.gz";,
+        "url_template": "https://github.com/<owner>/<repo>/archive/<rev>.tar.gz"
+    },
+    "nixpkgs": {
+        "branch": "gnome",
+        "description": "Nix Packages collection",
+        "homepage": "",
+        "owner": "NixOS",
+        "repo": "nixpkgs",
+        "rev": "c4a0b65a2819e19446d7dd7fba2209be7edf8379",
+        "sha256": "10jwxcixxbd4bnapzl8dz6cn3gmibqldhz0n3vhgx90njhycfbvl",
+        "type": "tarball",
+        "url": "https://github.com/NixOS/nixpkgs/archive/c4a0b65a2819e19446d7dd7fba2209be7edf8379.tar.gz";,
+        "url_template": "https://github.com/<owner>/<repo>/archive/<rev>.tar.gz"
+    }
+}
diff --git a/nix/sources.nix b/nix/sources.nix
new file mode 100644
index 0000000..9a01c8a
--- /dev/null
+++ b/nix/sources.nix
@@ -0,0 +1,194 @@
+# This file has been generated by Niv.
+
+let
+
+  #
+  # The fetchers. fetch_<type> fetches specs of type <type>.
+  #
+
+  fetch_file = pkgs: name: spec:
+    let
+      name' = sanitizeName name + "-src";
+    in
+      if spec.builtin or true then
+        builtins_fetchurl { inherit (spec) url sha256; name = name'; }
+      else
+        pkgs.fetchurl { inherit (spec) url sha256; name = name'; };
+
+  fetch_tarball = pkgs: name: spec:
+    let
+      name' = sanitizeName name + "-src";
+    in
+      if spec.builtin or true then
+        builtins_fetchTarball { name = name'; inherit (spec) url sha256; }
+      else
+        pkgs.fetchzip { name = name'; inherit (spec) url sha256; };
+
+  fetch_git = name: spec:
+    let
+      ref =
+        if spec ? ref then spec.ref else
+          if spec ? branch then "refs/heads/${spec.branch}" else
+            if spec ? tag then "refs/tags/${spec.tag}" else
+              abort "In git source '${name}': Please specify `ref`, `tag` or `branch`!";
+      submodules = if spec ? submodules then spec.submodules else false;
+      submoduleArg =
+        let
+          nixSupportsSubmodules = builtins.compareVersions builtins.nixVersion "2.4" >= 0;
+          emptyArgWithWarning =
+            if submodules == true
+            then
+              builtins.trace
+                (
+                  "The niv input \"${name}\" uses submodules "
+                  + "but your nix's (${builtins.nixVersion}) builtins.fetchGit "
+                  + "does not support them"
+                )
+                {}
+            else {};
+        in
+          if nixSupportsSubmodules
+          then { inherit submodules; }
+          else emptyArgWithWarning;
+    in
+      builtins.fetchGit
+        ({ url = spec.repo; inherit (spec) rev; inherit ref; } // submoduleArg);
+
+  fetch_local = spec: spec.path;
+
+  fetch_builtin-tarball = name: throw
+    ''[${name}] The niv type "builtin-tarball" is deprecated. You should instead use `builtin = true`.
+        $ niv modify ${name} -a type=tarball -a builtin=true'';
+
+  fetch_builtin-url = name: throw
+    ''[${name}] The niv type "builtin-url" will soon be deprecated. You should instead use `builtin = true`.
+        $ niv modify ${name} -a type=file -a builtin=true'';
+
+  #
+  # Various helpers
+  #
+
+  # https://github.com/NixOS/nixpkgs/pull/83241/files#diff-c6f540a4f3bfa4b0e8b6bafd4cd54e8bR695
+  sanitizeName = name:
+    (
+      concatMapStrings (s: if builtins.isList s then "-" else s)
+        (
+          builtins.split "[^[:alnum:]+._?=-]+"
+            ((x: builtins.elemAt (builtins.match "\\.*(.*)" x) 0) name)
+        )
+    );
+
+  # The set of packages used when specs are fetched using non-builtins.
+  mkPkgs = sources: system:
+    let
+      sourcesNixpkgs =
+        import (builtins_fetchTarball { inherit (sources.nixpkgs) url sha256; }) { inherit system; };
+      hasNixpkgsPath = builtins.any (x: x.prefix == "nixpkgs") builtins.nixPath;
+      hasThisAsNixpkgsPath = <nixpkgs> == ./.;
+    in
+      if builtins.hasAttr "nixpkgs" sources
+      then sourcesNixpkgs
+      else if hasNixpkgsPath && ! hasThisAsNixpkgsPath then
+        import <nixpkgs> {}
+      else
+        abort
+          ''
+            Please specify either <nixpkgs> (through -I or NIX_PATH=nixpkgs=...) or
+            add a package called "nixpkgs" to your sources.json.
+          '';
+
+  # The actual fetching function.
+  fetch = pkgs: name: spec:
+
+    if ! builtins.hasAttr "type" spec then
+      abort "ERROR: niv spec ${name} does not have a 'type' attribute"
+    else if spec.type == "file" then fetch_file pkgs name spec
+    else if spec.type == "tarball" then fetch_tarball pkgs name spec
+    else if spec.type == "git" then fetch_git name spec
+    else if spec.type == "local" then fetch_local spec
+    else if spec.type == "builtin-tarball" then fetch_builtin-tarball name
+    else if spec.type == "builtin-url" then fetch_builtin-url name
+    else
+      abort "ERROR: niv spec ${name} has unknown type ${builtins.toJSON spec.type}";
+
+  # If the environment variable NIV_OVERRIDE_${name} is set, then use
+  # the path directly as opposed to the fetched source.
+  replace = name: drv:
+    let
+      saneName = stringAsChars (c: if isNull (builtins.match "[a-zA-Z0-9]" c) then "_" else c) name;
+      ersatz = builtins.getEnv "NIV_OVERRIDE_${saneName}";
+    in
+      if ersatz == "" then drv else
+        # this turns the string into an actual Nix path (for both absolute and
+        # relative paths)
+        if builtins.substring 0 1 ersatz == "/" then /. + ersatz else /. + builtins.getEnv "PWD" + 
"/${ersatz}";
+
+  # Ports of functions for older nix versions
+
+  # a Nix version of mapAttrs if the built-in doesn't exist
+  mapAttrs = builtins.mapAttrs or (
+    f: set: with builtins;
+    listToAttrs (map (attr: { name = attr; value = f attr set.${attr}; }) (attrNames set))
+  );
+
+  # https://github.com/NixOS/nixpkgs/blob/0258808f5744ca980b9a1f24fe0b1e6f0fecee9c/lib/lists.nix#L295
+  range = first: last: if first > last then [] else builtins.genList (n: first + n) (last - first + 1);
+
+  # https://github.com/NixOS/nixpkgs/blob/0258808f5744ca980b9a1f24fe0b1e6f0fecee9c/lib/strings.nix#L257
+  stringToCharacters = s: map (p: builtins.substring p 1 s) (range 0 (builtins.stringLength s - 1));
+
+  # https://github.com/NixOS/nixpkgs/blob/0258808f5744ca980b9a1f24fe0b1e6f0fecee9c/lib/strings.nix#L269
+  stringAsChars = f: s: concatStrings (map f (stringToCharacters s));
+  concatMapStrings = f: list: concatStrings (map f list);
+  concatStrings = builtins.concatStringsSep "";
+
+  # https://github.com/NixOS/nixpkgs/blob/8a9f58a375c401b96da862d969f66429def1d118/lib/attrsets.nix#L331
+  optionalAttrs = cond: as: if cond then as else {};
+
+  # fetchTarball version that is compatible between all the versions of Nix
+  builtins_fetchTarball = { url, name ? null, sha256 }@attrs:
+    let
+      inherit (builtins) lessThan nixVersion fetchTarball;
+    in
+      if lessThan nixVersion "1.12" then
+        fetchTarball ({ inherit url; } // (optionalAttrs (!isNull name) { inherit name; }))
+      else
+        fetchTarball attrs;
+
+  # fetchurl version that is compatible between all the versions of Nix
+  builtins_fetchurl = { url, name ? null, sha256 }@attrs:
+    let
+      inherit (builtins) lessThan nixVersion fetchurl;
+    in
+      if lessThan nixVersion "1.12" then
+        fetchurl ({ inherit url; } // (optionalAttrs (!isNull name) { inherit name; }))
+      else
+        fetchurl attrs;
+
+  # Create the final "sources" from the config
+  mkSources = config:
+    mapAttrs (
+      name: spec:
+        if builtins.hasAttr "outPath" spec
+        then abort
+          "The values in sources.json should not have an 'outPath' attribute"
+        else
+          spec // { outPath = replace name (fetch config.pkgs name spec); }
+    ) config.sources;
+
+  # The "config" used by the fetchers
+  mkConfig =
+    { sourcesFile ? if builtins.pathExists ./sources.json then ./sources.json else null
+    , sources ? if isNull sourcesFile then {} else builtins.fromJSON (builtins.readFile sourcesFile)
+    , system ? builtins.currentSystem
+    , pkgs ? mkPkgs sources system
+    }: rec {
+      # The sources, i.e. the attribute set of spec name to spec
+      inherit sources;
+
+      # The "pkgs" (evaluated nixpkgs) to use for e.g. non-builtin fetchers
+      inherit pkgs;
+    };
+
+in
+mkSources (mkConfig {}) // { __functor = _: settings: mkSources (mkConfig settings); }
diff --git a/shell.nix b/shell.nix
new file mode 100644
index 0000000..c66c503
--- /dev/null
+++ b/shell.nix
@@ -0,0 +1,8 @@
+{
+  pkgs ? null,
+  doCheck ? true,
+}:
+import ./default.nix {
+  inherit doCheck pkgs;
+  shell = true;
+}