[polari] build: Update meson style

[Florian Müllner <fmuellner src gnome org>]

commit f9c83dcab9d39fb1e79808763757e658e58b8590
Author: Florian Müllner <fmuellner gnome org>
Date:   Mon May 29 22:17:04 2017 +0200

    build: Update meson style
    
    Follow the meson convention of two-space indentation and no aligned
    parameters.

 data/appdata/meson.build |   20 +++++----
 data/icons/meson.build   |    3 +-
 data/meson.build         |   44 +++++++++++----------
 help/meson.build         |   33 +++++++++-------
 meson.build              |   41 ++++++++++----------
 po/meson.build           |    3 +-
 src/meson.build          |   96 ++++++++++++++++++++++++++-------------------
 7 files changed, 132 insertions(+), 108 deletions(-)
---
diff --git a/data/appdata/meson.build b/data/appdata/meson.build
index 8d2bf89..a01a4a4 100644
--- a/data/appdata/meson.build
+++ b/data/appdata/meson.build
@@ -1,14 +1,16 @@
 appdata = app_id + '.appdata.xml'
-i18n.merge_file('appdata',
-                input: appdata + '.in',
-                output: appdata,
-                po_dir: '../../po',
-                install: true,
-                install_dir: appdatadir)
+i18n.merge_file(appdata,
+  input: appdata + '.in',
+  output: appdata,
+  po_dir: '../../po',
+  install: true,
+  install_dir: appdatadir
+)
 
 if (appstream_util.found())
   test('Validating ' + appdata,
-       appstream_util,
-       args: ['validate', '--nonet', appdata],
-       workdir: meson.current_build_dir())
+    appstream_util,
+    args: ['validate', '--nonet', appdata],
+    workdir: meson.current_build_dir()
+  )
 endif
diff --git a/data/icons/meson.build b/data/icons/meson.build
index 89b7e41..eff6e4b 100644
--- a/data/icons/meson.build
+++ b/data/icons/meson.build
@@ -1,2 +1 @@
-install_subdir('hicolor',
-               install_dir: icondir)
+install_subdir('hicolor', install_dir: icondir)
diff --git a/data/meson.build b/data/meson.build
index 0f97a8f..74a1935 100644
--- a/data/meson.build
+++ b/data/meson.build
@@ -2,35 +2,39 @@ subdir('appdata')
 subdir('icons')
 
 desktop_file = app_id + '.desktop'
-i18n.merge_file('desktop',
-                input: desktop_file + '.in',
-                output: desktop_file,
-                po_dir: '../po',
-                install: true,
-                install_dir: desktopdir,
-                type: 'desktop')
+i18n.merge_file(desktop_file,
+  input: desktop_file + '.in',
+  output: desktop_file,
+  po_dir: '../po',
+  install: true,
+  install_dir: desktopdir,
+  type: 'desktop'
+)
 
 if (desktop_file_validate.found())
   test('Validating ' + desktop_file,
-       desktop_file_validate,
-       args: [desktop_file],
-       workdir: meson.current_build_dir())
+    desktop_file_validate,
+    args: [desktop_file],
+    workdir: meson.current_build_dir()
+  )
 endif
 
 service_conf = configuration_data()
 service_conf.set('bindir', join_paths(prefix, bindir))
 
-services = ['org.freedesktop.Telepathy.Client.Polari.service',
-            app_id + '.service']
+services = [
+  'org.freedesktop.Telepathy.Client.Polari.service',
+  app_id + '.service'
+]
 
 foreach s : services
-  configure_file(input: s + '.in',
-                 output: s,
-                 configuration: service_conf,
-                 install_dir: servicedir)
+  configure_file(
+    input: s + '.in',
+    output: s,
+    configuration: service_conf,
+    install_dir: servicedir
+  )
 endforeach
 
-install_data(app_id + '.gschema.xml',
-             install_dir: schemadir)
-install_data(['Polari.client'],
-             install_dir: tpclientdir)
+install_data(app_id + '.gschema.xml', install_dir: schemadir)
+install_data('Polari.client', install_dir: tpclientdir)
diff --git a/help/meson.build b/help/meson.build
index 408b542..d46c652 100644
--- a/help/meson.build
+++ b/help/meson.build
@@ -1,15 +1,20 @@
 gnome.yelp(app_id,
-           sources: ['index.page',
-                     'introduction.page',
-                     'irc-commands.page',
-                     'irc-join-room.page',
-                     'irc-nick-password.page',
-                     'irc-start-conversation.page',
-                     'legal.xml',
-                     'network-connect.page',
-                     'overview.page',
-                     'sharing.page'],
-           media: ['images/polari-paste.png',
-                   'images/polari-screenshot.png',
-                   'images/Polari.png'],
-           languages: ['cs', 'de', 'es', 'fr', 'hu', 'pt_BR', 'sv'])
+  sources: [
+    'index.page',
+    'introduction.page',
+    'irc-commands.page',
+    'irc-join-room.page',
+    'irc-nick-password.page',
+    'irc-start-conversation.page',
+    'legal.xml',
+    'network-connect.page',
+    'overview.page',
+    'sharing.page'
+  ],
+  media: [
+    'images/polari-paste.png',
+    'images/polari-screenshot.png',
+    'images/Polari.png'
+  ],
+  languages: ['cs', 'de', 'es', 'fr', 'hu', 'pt_BR', 'sv']
+)
diff --git a/meson.build b/meson.build
index 3074586..1e9459e 100644
--- a/meson.build
+++ b/meson.build
@@ -1,41 +1,42 @@
 project('polari', 'c',
-        version: '3.25.1',
-        meson_version: '>= 0.37.0',
-        license: 'GPL2+')
+  version: '3.25.1',
+  meson_version: '>= 0.37.0',
+  license: 'GPL2+'
+)
 
 app_id = 'org.gnome.Polari'
 
-gnome  = import('gnome')
-i18n   = import('i18n')
+gnome = import('gnome')
+i18n = import('i18n')
 
 prefix = get_option('prefix')
 
-bindir  = get_option('bindir')
-libdir  = get_option('libdir')
+bindir = get_option('bindir')
+libdir = get_option('libdir')
 datadir = get_option('datadir')
 
-pkglibdir  = join_paths(libdir, meson.project_name())
+pkglibdir = join_paths(libdir, meson.project_name())
 pkgdatadir = join_paths(datadir, meson.project_name())
 
-appdatadir  = join_paths(datadir, 'appdata')
-desktopdir  = join_paths(datadir, 'applications')
-icondir     = join_paths(datadir, 'icons')
-schemadir   = join_paths(datadir, 'glib-2.0', 'schemas')
-servicedir  = join_paths(datadir, 'dbus-1', 'services')
+appdatadir = join_paths(datadir, 'appdata')
+desktopdir = join_paths(datadir, 'applications')
+icondir = join_paths(datadir, 'icons')
+schemadir = join_paths(datadir, 'glib-2.0', 'schemas')
+servicedir = join_paths(datadir, 'dbus-1', 'services')
 tpclientdir = join_paths(datadir, 'telepathy', 'clients')
-girdir      = join_paths(pkgdatadir, 'gir-1.0')
-typelibdir  = join_paths(pkglibdir, 'girepository-1.0')
+girdir = join_paths(pkgdatadir, 'gir-1.0')
+typelibdir = join_paths(pkglibdir, 'girepository-1.0')
 
 gjs_console = find_program('gjs')
 
 desktop_file_validate = find_program('desktop-file-validate', required: false)
-appstream_util        = find_program('appstream-util', required: false)
+appstream_util = find_program('appstream-util', required: false)
 
-gio            = dependency('gio-2.0', version: '>= 2.43.4')
-gtk3           = dependency('gtk+-3.0', version: '>= 3.21.6')
+gio = dependency('gio-2.0', version: '>= 2.43.4')
+gtk3 = dependency('gtk+-3.0', version: '>= 3.21.6')
 telepathy_glib = dependency('telepathy-glib')
-girepository   = dependency('gobject-introspection-1.0')
-gjs            = dependency('gjs-1.0')
+girepository = dependency('gobject-introspection-1.0')
+gjs = dependency('gjs-1.0')
 
 cc = meson.get_compiler('c')
 if (cc.has_function('strcasestr'))
diff --git a/po/meson.build b/po/meson.build
index fb83741..dd7d7aa 100644
--- a/po/meson.build
+++ b/po/meson.build
@@ -1,2 +1 @@
-i18n.gettext('polari',
-             args: ['--from-code=UTF-8'])
+i18n.gettext('polari', args: ['--from-code=UTF-8'])
diff --git a/src/meson.build b/src/meson.build
index f5e56e2..6135230 100644
--- a/src/meson.build
+++ b/src/meson.build
@@ -2,52 +2,66 @@ script_conf = configuration_data()
 script_conf.set('GJS', gjs_console.path())
 
 script = 'polari-accounts'
-configure_file(input: script + '.in',
-               output: script,
-               configuration: script_conf)
+configure_file(
+  input: script + '.in',
+  output: script,
+  configuration: script_conf
+)
 
-data_resources = gnome.compile_resources('data-resources',
-                                         '../data/@0  data gresource xml'.format(app_id),
-                                         source_dir: '../data',
-                                         c_name: 'data_resources')
+data_resources = gnome.compile_resources(
+  'data-resources',
+  '../data/@0  data gresource xml'.format(app_id),
+  source_dir: '../data',
+  c_name: 'data_resources'
+)
 
-src_resources = gnome.compile_resources('src-resources',
-                                        '@0  src gresource xml'.format(app_id),
-                                        c_name: 'src_resources')
+src_resources = gnome.compile_resources(
+  'src-resources',
+  '@0  src gresource xml'.format(app_id),
+  c_name: 'src_resources'
+)
 
-exeargs = ['-DPACKAGE_NAME="polari"',
-           '-DPACKAGE_VERSION="@0@"'.format(meson.project_version()),
-           '-DPREFIX="@0@"'.format(prefix),
-           '-DLIBDIR="@0@"'.format(join_paths(prefix, libdir)),
-           '-DPKGLIBDIR="@0@"'.format(join_paths(prefix, pkglibdir))]
-polari = executable('polari',
-                    ['polari.c', src_resources, data_resources],
-                    dependencies: [gio, girepository, gjs],
-                    c_args: exeargs,
-                    install: true)
+exeargs = [
+  '-DPACKAGE_NAME="polari"',
+  '-DPACKAGE_VERSION="@0@"'.format(meson.project_version()),
+  '-DPREFIX="@0@"'.format(prefix),
+  '-DLIBDIR="@0@"'.format(join_paths(prefix, libdir)),
+  '-DPKGLIBDIR="@0@"'.format(join_paths(prefix, pkglibdir))
+]
+polari = executable('polari', ['polari.c', src_resources, data_resources],
+  dependencies: [gio, girepository, gjs],
+  c_args: exeargs,
+  install: true
+)
 
-libsources = ['lib/polari-drag-helper.c',
-              'lib/polari-drag-helper.h',
-              'lib/polari-room.c',
-              'lib/polari-room.h',
-              'lib/polari-util.c',
-              'lib/polari-util.h']
+libsources = [
+  'lib/polari-drag-helper.c',
+  'lib/polari-drag-helper.h',
+  'lib/polari-room.c',
+  'lib/polari-room.h',
+  'lib/polari-util.c',
+  'lib/polari-util.h'
+]
 
-libargs = ['-DG_LOG_USE_STRUCTURED',
-           '-DG_LOG_DOMAIN="Polari"']
+libargs = [
+  '-DG_LOG_USE_STRUCTURED',
+  '-DG_LOG_DOMAIN="Polari"'
+]
 libpolari = shared_library('polari-1.0', libsources,
-                           dependencies: [gio, gtk3, telepathy_glib],
-                           c_args: libargs,
-                           install: true,
-                           install_dir: pkglibdir)
+  dependencies: [gio, gtk3, telepathy_glib],
+  c_args: libargs,
+  install: true,
+  install_dir: pkglibdir
+)
 
 gnome.generate_gir(libpolari,
-                   sources: libsources,
-                   nsversion: '1.0',
-                   namespace: 'Polari',
-                   symbol_prefix: 'polari',
-                   identifier_prefix: 'Polari',
-                   includes: ['Gio-2.0', 'Gtk-3.0', 'TelepathyGLib-0.12'],
-                   install_dir_gir: girdir,
-                   install_dir_typelib: typelibdir,
-                   install: true)
+  sources: libsources,
+  nsversion: '1.0',
+  namespace: 'Polari',
+  symbol_prefix: 'polari',
+  identifier_prefix: 'Polari',
+  includes: ['Gio-2.0', 'Gtk-3.0', 'TelepathyGLib-0.12'],
+  install_dir_gir: girdir,
+  install_dir_typelib: typelibdir,
+  install: true
+)