[gnome-backgrounds] build: Support the meson build system

[Florian Müllner <fmuellner src gnome org>]

commit 1e4bec09391f4a07d92000a85b4ed9f9821d9f84
Author: Florian Müllner <fmuellner gnome org>
Date:   Tue May 30 02:06:52 2017 +0200

    build: Support the meson build system
    
    Meson is on track to replace autotools as the build system of choice,
    so supporting it seems like a good idea ...
    
    https://bugzilla.gnome.org/show_bug.cgi?id=783224

 backgrounds/meson.build |   48 +++++++++++++++++++++++++++++++++++++++++++++++
 meson.build             |   15 ++++++++++++++
 po/meson.build          |    1 +
 3 files changed, 64 insertions(+), 0 deletions(-)
---
diff --git a/backgrounds/meson.build b/backgrounds/meson.build
new file mode 100644
index 0000000..5345698
--- /dev/null
+++ b/backgrounds/meson.build
@@ -0,0 +1,48 @@
+dataconf = configuration_data()
+dataconf.set('BACKGROUNDDIR', backgrounddir)
+dataconf.set('datadir', datadir)
+
+adwaita_timed = configure_file(
+  input: 'adwaita-timed.xml.in',
+  output: 'adwaita-timed.xml',
+  configuration: dataconf
+)
+
+backgrounds = [
+  'adwaita-day.jpg',
+  'adwaita-lock.jpg',
+  'adwaita-morning.jpg',
+  'adwaita-night.jpg',
+  'Bokeh_Tails.jpg',
+  'Chmiri.jpg',
+  'Dark_Ivy.jpg',
+  'Fabric.jpg',
+  'Flowerbed.jpg',
+  'Godafoss_Iceland.jpg',
+  'Icescape.jpg',
+  'Mirror.jpg',
+  'Road.jpg',
+  'Sandstone.jpg',
+  'Signpost_of_the_Shadows.jpg',
+  'Stones.jpg',
+  'Terraform-green.jpg',
+  'Waterfalls.jpg',
+  'Waves.jpg'
+]
+
+install_data([adwaita_timed] + backgrounds, install_dir: backgrounddir)
+
+foreach metadata : ['gnome-backgrounds.xml', 'adwaita.xml']
+  i18n.merge_file(metadata,
+    input: configure_file(
+      input: metadata + '.in.in',
+      output: metadata + '.in',
+      configuration: dataconf
+    ),
+    output: metadata,
+    po_dir: '../po',
+    data_dirs: '..',
+    install: true,
+    install_dir: metadatadir
+  )
+endforeach
diff --git a/meson.build b/meson.build
new file mode 100644
index 0000000..f0b210b
--- /dev/null
+++ b/meson.build
@@ -0,0 +1,15 @@
+project('gnome-backgrounds',
+  version: '3.24.0',
+  meson_version: '>= 0.41.0'
+)
+
+i18n = import('i18n')
+
+prefix = get_option('prefix')
+
+datadir = join_paths(prefix, get_option('datadir'))
+backgrounddir = join_paths(datadir, 'backgrounds', 'gnome')
+metadatadir = join_paths(datadir, 'gnome-background-properties')
+
+subdir('backgrounds')
+subdir('po')
diff --git a/po/meson.build b/po/meson.build
new file mode 100644
index 0000000..4861a84
--- /dev/null
+++ b/po/meson.build
@@ -0,0 +1 @@
+i18n.gettext('gnome-backgrounds', preset: 'glib', data_dirs: '..')