[gnome-settings-daemon] build: Stop using deprecated macros in configure.ac

[Bastien Nocera <hadess src gnome org>]

commit eea8d7e861162f4e7e0de409372a1a3e5cb8f40e
Author: Philip Withnall <withnall endlessm com>
Date:   Thu Feb 9 10:57:34 2017 +0000

    build: Stop using deprecated macros in configure.ac
    
    Results of using autoupdate to move away from deprecated macros in
    configure.ac.
    
    https://bugzilla.gnome.org/show_bug.cgi?id=778383

 configure.ac |   32 +++++++++++++-------------------
 1 files changed, 13 insertions(+), 19 deletions(-)
---
diff --git a/configure.ac b/configure.ac
index dd6b719..a2fa53f 100644
--- a/configure.ac
+++ b/configure.ac
@@ -1,4 +1,4 @@
-AC_PREREQ([2.60])
+AC_PREREQ([2.69])
 
 AC_INIT([gnome-settings-daemon],
         [3.23.3],
@@ -17,11 +17,11 @@ m4_define([gsd_api_version],[gsd_api_version_major.gsd_api_version_minor])
 GSD_API_VERSION="gsd_api_version"
 AC_SUBST(GSD_API_VERSION)
 
-AC_STDC_HEADERS
+AC_HEADER_STDC
 AC_PROG_CXX
 AM_PROG_CC_C_O
 AC_PROG_CC_C99
-AC_PROG_LIBTOOL
+LT_INIT
 
 AC_HEADER_STDC
 
@@ -73,7 +73,7 @@ AC_SUBST([GSD_PLUGIN_LDFLAGS])
 AC_PATH_PROG(GLIB_GENMARSHAL, glib-genmarshal)
 AC_PATH_PROG([GLIB_MKENUMS],[glib-mkenums])
 
-AC_CHECK_LIBM
+LT_LIB_M
 AC_SUBST(LIBM)
 
 dnl ================================================================
@@ -126,7 +126,7 @@ dnl ---------------------------------------------------------------------------
 dnl - Check for libwayland-client
 dnl ---------------------------------------------------------------------------
 AC_ARG_ENABLE(wayland,
-        AC_HELP_STRING([--disable-wayland], [Disable wayland support (default: auto)]),
+        AS_HELP_STRING([--disable-wayland],[Disable wayland support (default: auto)]),
         enable_wayland=$enableval, enable_wayland=auto)
 if test x$enable_wayland != xno; then
         PKG_CHECK_MODULES(WAYLAND, wayland-client, have_wayland=yes, have_wayland=no)
@@ -304,8 +304,7 @@ dnl smartcard section
 dnl ==============================================
 have_smartcard_support=false
 AC_ARG_ENABLE(smartcard-support,
-  AC_HELP_STRING([--disable-smartcard-support],
-                 [turn off smartcard support]),
+  AS_HELP_STRING([--disable-smartcard-support],[turn off smartcard support]),
        [case "${enableval}" in
                yes) WANT_SMARTCARD_SUPPORT=yes ;;
                no)  WANT_SMARTCARD_SUPPORT=no ;;
@@ -326,8 +325,7 @@ AC_SUBST(NSS_CFLAGS)
 AC_SUBST(NSS_LIBS)
 
 AC_ARG_WITH(nssdb,
-  AC_HELP_STRING([--with-nssdb],
-                 [where system NSS database is]))
+  AS_HELP_STRING([--with-nssdb],[where system NSS database is]))
 
 NSS_DATABASE=""
 if test "x$have_smartcard_support" = "xtrue"; then
@@ -430,8 +428,7 @@ PKG_CHECK_MODULES(SHARING,
 # Enable Profiling
 # ---------------------------------------------------------------------------
 AC_ARG_ENABLE(profiling,
-       [AC_HELP_STRING([--enable-profiling],
-       [turn on profiling])],
+       [AS_HELP_STRING([--enable-profiling],[turn on profiling])],
        , enable_profiling=no)
 if test "x$enable_profiling" = "xyes"; then
     AC_DEFINE(ENABLE_PROFILING,1,[enable profiling])
@@ -455,8 +452,7 @@ dnl ---------------------------------------------------------------------------
 # Turn on the additional warnings last, so warnings don't affect other tests.
 
 AC_ARG_ENABLE(more-warnings,
-       [AC_HELP_STRING([--enable-more-warnings],
-       [Maximum compiler warnings])],
+       [AS_HELP_STRING([--enable-more-warnings],[Maximum compiler warnings])],
        set_more_warnings="$enableval",[
                if test -d $srcdir/.git; then
                        set_more_warnings=yes
@@ -478,9 +474,7 @@ if test "$GCC" = "yes" -a "$set_more_warnings" != "no"; then
                 SAVE_CFLAGS="$CFLAGS"
                 CFLAGS="$CFLAGS $option"
                 AC_MSG_CHECKING([whether gcc understands $option])
-                AC_TRY_COMPILE([], [],
-                        has_option=yes,
-                        has_option=no,)
+                AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[]], [[]])],[has_option=yes],[has_option=no])
                 if test $has_option = no; then
                         CFLAGS="$SAVE_CFLAGS"
                 fi
@@ -497,8 +491,7 @@ fi
 # Enable Debug
 #
 AC_ARG_ENABLE(debug,
-       [AC_HELP_STRING([--enable-debug],
-       [turn on debugging])],
+       [AS_HELP_STRING([--enable-debug],[turn on debugging])],
        , enable_debug=yes)
 if test "$enable_debug" = "yes"; then
        DEBUG_CFLAGS="-DG_ENABLE_DEBUG"
@@ -511,7 +504,7 @@ else
 fi
 AC_SUBST(DEBUG_CFLAGS)
 
-AC_OUTPUT([
+AC_CONFIG_FILES([
 Makefile
 gnome-settings-daemon/Makefile
 plugins/Makefile
@@ -553,6 +546,7 @@ data/org.gnome.settings-daemon.peripherals.wacom.gschema.xml.in
 po/Makefile.in
 tests/Makefile
 ])
+AC_OUTPUT
 
 dnl ---------------------------------------------------------------------------
 dnl - Show summary