[mm-common] Add macros/mm-ax_cxx_compile_stdcxx_11.m4

[Kjell Ahlstedt <kjellahl src gnome org>]

commit 0cb42dc92a380b2033f92bb7f31fc8a0dc0b278a
Author: Kjell Ahlstedt <kjell ahlstedt bredband net>
Date:   Mon Jul 13 15:58:31 2015 +0200

    Add macros/mm-ax_cxx_compile_stdcxx_11.m4
    
    * README: Describe mm-ax_cxx_compile_stdcxx_11.m4.
    * Makefile.am: Distribute and install mm-ax_cxx_compile_stdcxx_11.m4.
    * macros/mm-ax_cxx_compile_stdcxx_11.m4: New file.
    * skeletonmm/configure.ac: Add MM_AX_CXX_COMPILE_STDCXX_11.
    Bug #751432.

 Makefile.am                           |    3 +-
 README                                |    7 ++
 macros/mm-ax_cxx_compile_stdcxx_11.m4 |  168 +++++++++++++++++++++++++++++++++
 skeletonmm/configure.ac               |    2 +
 4 files changed, 179 insertions(+), 1 deletions(-)
---
diff --git a/Makefile.am b/Makefile.am
index 8db5e8b..caf0cb2 100644
--- a/Makefile.am
+++ b/Makefile.am
@@ -29,10 +29,11 @@ dist_build_support_DATA =           \
        build/doc-reference.am          \
        build/generate-binding.am
 
-# These are installed so that mm-common-prepare can copy them into projects at autogen.sh time:
+# These are installed so that aclocal can copy them into aclocal.m4 at autogen.sh time:
 aclocal_macrodir = $(datadir)/aclocal
 aclocal_macro_DATA = macros/mm-common.m4
 dist_aclocal_macro_DATA =              \
+       macros/mm-ax_cxx_compile_stdcxx_11.m4           \
        macros/mm-dietlib.m4            \
        macros/mm-doc.m4                \
        macros/mm-module.m4             \
diff --git a/README b/README
index aa5db10..a50fc0e 100644
--- a/README
+++ b/README
@@ -113,6 +113,13 @@ macros/mm-dietlib.m4:
   binary size of the generated binding library, typically for embedded use.
   The MM_PROG_GCC_VISIBILITY macro is defined in this file as well.
 
+macros/mm-ax_cxx_compile_stdcxx_11.m4:
+  Implements the MM_AX_CXX_COMPILE_STDCXX_11() macro to test and set flags
+  for C++11 compatibility of the C++ compiler. This is identical to the
+  AX_CXX_COMPILE_STDCXX_11() macro described at
+  http://www.gnu.org/software/autoconf-archive/ax_cxx_compile_stdcxx_11.html,
+  except for the MM_ prefix.
+
 Automake include files
 ----------------------
 
diff --git a/macros/mm-ax_cxx_compile_stdcxx_11.m4 b/macros/mm-ax_cxx_compile_stdcxx_11.m4
new file mode 100644
index 0000000..b83fac4
--- /dev/null
+++ b/macros/mm-ax_cxx_compile_stdcxx_11.m4
@@ -0,0 +1,168 @@
+# ============================================================================
+#  http://www.gnu.org/software/autoconf-archive/ax_cxx_compile_stdcxx_11.html
+# ============================================================================
+#
+# SYNOPSIS
+#
+#   AX_CXX_COMPILE_STDCXX_11([ext|noext],[mandatory|optional])
+#
+# DESCRIPTION
+#
+#   Check for baseline language coverage in the compiler for the C++11
+#   standard; if necessary, add switches to CXXFLAGS to enable support.
+#
+#   The first argument, if specified, indicates whether you insist on an
+#   extended mode (e.g. -std=gnu++11) or a strict conformance mode (e.g.
+#   -std=c++11).  If neither is specified, you get whatever works, with
+#   preference for an extended mode.
+#
+#   The second argument, if specified 'mandatory' or if left unspecified,
+#   indicates that baseline C++11 support is required and that the macro
+#   should error out if no mode with that support is found.  If specified
+#   'optional', then configuration proceeds regardless, after defining
+#   HAVE_CXX11 if and only if a supporting mode is found.
+#
+# LICENSE
+#
+#   Copyright (c) 2008 Benjamin Kosnik <bkoz redhat com>
+#   Copyright (c) 2012 Zack Weinberg <zackw panix com>
+#   Copyright (c) 2013 Roy Stogner <roystgnr ices utexas edu>
+#   Copyright (c) 2014, 2015 Google Inc.; contributed by Alexey Sokolov <sokolov google com>
+#
+#   Copying and distribution of this file, with or without modification, are
+#   permitted in any medium without royalty provided the copyright notice
+#   and this notice are preserved. This file is offered as-is, without any
+#   warranty.
+
+#serial 11
+
+m4_define([_AX_CXX_COMPILE_STDCXX_11_testbody], [[
+  template <typename T>
+    struct check
+    {
+      static_assert(sizeof(int) <= sizeof(T), "not big enough");
+    };
+
+    struct Base {
+    virtual void f() {}
+    };
+    struct Child : public Base {
+    virtual void f() override {}
+    };
+
+    typedef check<check<bool>> right_angle_brackets;
+
+    int a;
+    decltype(a) b;
+
+    typedef check<int> check_type;
+    check_type c;
+    check_type&& cr = static_cast<check_type&&>(c);
+
+    auto d = a;
+    auto l = [](){};
+    // Prevent Clang error: unused variable 'l' [-Werror,-Wunused-variable]
+    struct use_l { use_l() { l(); } };
+
+    // http://stackoverflow.com/questions/13728184/template-aliases-and-sfinae
+    // Clang 3.1 fails with headers of libstd++ 4.8.3 when using std::function because of this
+    namespace test_template_alias_sfinae {
+        struct foo {};
+
+        template<typename T>
+        using member = typename T::member_type;
+
+        template<typename T>
+        void func(...) {}
+
+        template<typename T>
+        void func(member<T>*) {}
+
+        void test();
+
+        void test() {
+            func<foo>(0);
+        }
+    }
+]])
+
+AC_DEFUN([AX_CXX_COMPILE_STDCXX_11], [dnl
+  m4_if([$1], [], [],
+        [$1], [ext], [],
+        [$1], [noext], [],
+        [m4_fatal([invalid argument `$1' to AX_CXX_COMPILE_STDCXX_11])])dnl
+  m4_if([$2], [], [ax_cxx_compile_cxx11_required=true],
+        [$2], [mandatory], [ax_cxx_compile_cxx11_required=true],
+        [$2], [optional], [ax_cxx_compile_cxx11_required=false],
+        [m4_fatal([invalid second argument `$2' to AX_CXX_COMPILE_STDCXX_11])])
+  AC_LANG_PUSH([C++])dnl
+  ac_success=no
+  AC_CACHE_CHECK(whether $CXX supports C++11 features by default,
+  ax_cv_cxx_compile_cxx11,
+  [AC_COMPILE_IFELSE([AC_LANG_SOURCE([_AX_CXX_COMPILE_STDCXX_11_testbody])],
+    [ax_cv_cxx_compile_cxx11=yes],
+    [ax_cv_cxx_compile_cxx11=no])])
+  if test x$ax_cv_cxx_compile_cxx11 = xyes; then
+    ac_success=yes
+  fi
+
+  m4_if([$1], [noext], [], [dnl
+  if test x$ac_success = xno; then
+    for switch in -std=gnu++11 -std=gnu++0x; do
+      cachevar=AS_TR_SH([ax_cv_cxx_compile_cxx11_$switch])
+      AC_CACHE_CHECK(whether $CXX supports C++11 features with $switch,
+                     $cachevar,
+        [ac_save_CXXFLAGS="$CXXFLAGS"
+         CXXFLAGS="$CXXFLAGS $switch"
+         AC_COMPILE_IFELSE([AC_LANG_SOURCE([_AX_CXX_COMPILE_STDCXX_11_testbody])],
+          [eval $cachevar=yes],
+          [eval $cachevar=no])
+         CXXFLAGS="$ac_save_CXXFLAGS"])
+      if eval test x\$$cachevar = xyes; then
+        CXXFLAGS="$CXXFLAGS $switch"
+        ac_success=yes
+        break
+      fi
+    done
+  fi])
+
+  m4_if([$1], [ext], [], [dnl
+  if test x$ac_success = xno; then
+    dnl HP's aCC needs +std=c++11 according to:
+    dnl http://h21007.www2.hp.com/portal/download/files/unprot/aCxx/PDF_Release_Notes/769149-001.pdf
+    for switch in -std=c++11 -std=c++0x +std=c++11; do
+      cachevar=AS_TR_SH([ax_cv_cxx_compile_cxx11_$switch])
+      AC_CACHE_CHECK(whether $CXX supports C++11 features with $switch,
+                     $cachevar,
+        [ac_save_CXXFLAGS="$CXXFLAGS"
+         CXXFLAGS="$CXXFLAGS $switch"
+         AC_COMPILE_IFELSE([AC_LANG_SOURCE([_AX_CXX_COMPILE_STDCXX_11_testbody])],
+          [eval $cachevar=yes],
+          [eval $cachevar=no])
+         CXXFLAGS="$ac_save_CXXFLAGS"])
+      if eval test x\$$cachevar = xyes; then
+        CXXFLAGS="$CXXFLAGS $switch"
+        ac_success=yes
+        break
+      fi
+    done
+  fi])
+  AC_LANG_POP([C++])
+  if test x$ax_cxx_compile_cxx11_required = xtrue; then
+    if test x$ac_success = xno; then
+      AC_MSG_ERROR([*** A compiler with support for C++11 language features is required.])
+    fi
+  else
+    if test x$ac_success = xno; then
+      HAVE_CXX11=0
+      AC_MSG_NOTICE([No compiler with C++11 support was found])
+    else
+      HAVE_CXX11=1
+      AC_DEFINE(HAVE_CXX11,1,
+                [define if the compiler supports basic C++11 syntax])
+    fi
+
+    AC_SUBST(HAVE_CXX11)
+  fi
+])
+
diff --git a/skeletonmm/configure.ac b/skeletonmm/configure.ac
index d6fb6b8..9eaafe8 100644
--- a/skeletonmm/configure.ac
+++ b/skeletonmm/configure.ac
@@ -40,6 +40,8 @@ MM_CONFIG_DOCTOOL_DIR([doc])
 AC_SUBST([SKELETONMM_SO_VERSION], [0:0:0])
 
 AC_PROG_CXX
+MM_AX_CXX_COMPILE_STDCXX_11([noext],[mandatory])
+
 AC_DISABLE_STATIC
 AC_LIBTOOL_WIN32_DLL
 AC_PROG_LIBTOOL