GNOME.org
 

[gnome-chat] Add telepathy-account-widgets submodule

commit 60b9a6cfc9f7ac07038071e2b266bb6de6af8906
Author: Debarshi Ray <debarshir gnome org>
Date:   Wed Sep 11 16:07:20 2013 +0200

    Add telepathy-account-widgets submodule

 .gitmodules               |    3 +
 Makefile.am               |    4 +-
 autogen.sh                |    5 ++
 configure.ac              |   16 +++++++
 m4/ax_config_dir.m4       |  109 +++++++++++++++++++++++++++++++++++++++++++++
 src/Makefile.am           |    2 +
 telepathy-account-widgets |    1 +
 7 files changed, 139 insertions(+), 1 deletions(-)
---
diff --git a/.gitmodules b/.gitmodules
new file mode 100644
index 0000000..6c30dad
--- /dev/null
+++ b/.gitmodules
@@ -0,0 +1,3 @@
+[submodule "telepathy-account-widgets"]
+       path = telepathy-account-widgets
+       url = git://git.gnome.org/telepathy-account-widgets.git
diff --git a/Makefile.am b/Makefile.am
index 7027236..f09e72f 100644
--- a/Makefile.am
+++ b/Makefile.am
@@ -1,4 +1,6 @@
-SUBDIRS = . data src po
+ACLOCAL_AMFLAGS = -I m4 -I telepathy-account-widgets ${ACLOCAL_FLAGS}
+
+SUBDIRS = . data telepathy-account-widgets src po
 
 INTLTOOL_FILES = \
        intltool-extract.in \
diff --git a/autogen.sh b/autogen.sh
index 0d4017d..8655b26 100755
--- a/autogen.sh
+++ b/autogen.sh
@@ -17,6 +17,11 @@ which gnome-autogen.sh || {
     exit 1
 }
 
+git submodule update --init --recursive
+
+cd telepathy-account-widgets
+sh autogen.sh --no-configure
+cd ..
 
 REQUIRED_AUTOCONF_VERSION=2.63
 REQUIRED_AUTOMAKE_VERSION=1.11
diff --git a/configure.ac b/configure.ac
index 0aea9ed..5281642 100644
--- a/configure.ac
+++ b/configure.ac
@@ -55,6 +55,22 @@ PKG_CHECK_MODULES(TP_LOGGER, [telepathy-logger-0.2 >= $TP_LOGGER_MIN_VERSION])
 GLIB_COMPILE_RESOURCES=`$PKG_CONFIG --variable glib_compile_resources gio-2.0`
 AC_SUBST(GLIB_COMPILE_RESOURCES)
 
+# telepathy-account-widgets
+
+prev_top_build_prefix=$ac_top_build_prefix
+prev_ac_configure_args=$ac_configure_args
+ac_configure_args="$ac_configure_args --with-cheese=no --disable-gudev"
+ac_configure_args="$ac_configure_args --with-pkgdatadir=${datadir}/gnome-chat"
+ac_configure_args="$ac_configure_args --with-icondir=${datadir}/icons"
+ac_configure_args="$ac_configure_args --with-gettext-package=gnome-chat-tpaw"
+ac_configure_args="$ac_configure_args --disable-schemas-compile --disable-settings"
+AX_CONFIG_DIR([telepathy-account-widgets])
+ac_top_build_prefix=$prev_top_build_prefix
+ac_configure_args=$prev_ac_configure_args
+
+export PKG_CONFIG_PATH=$PKG_CONFIG_PATH:"$ac_top_build_prefix"telepathy-account-widgets/
+PKG_CHECK_MODULES(TPAW, telepathy-account-widgets)
+
 AC_CONFIG_FILES([
 Makefile
 data/Makefile
diff --git a/m4/ax_config_dir.m4 b/m4/ax_config_dir.m4
new file mode 100644
index 0000000..0ba313f
--- /dev/null
+++ b/m4/ax_config_dir.m4
@@ -0,0 +1,109 @@
+dnl Copied from Audacity 1.3.10 which itself is licensed under the GPL v2 or
+dnl any later version
+
+dnl Function to configure a sub-library now, because we need to know the result
+dnl of the configuration now in order to take decisions.
+dnl We don't worry about whether the configuration worked or not - it is
+dnl assumed that the next thing after this will be a package-specific check to
+dnl see if the package is actually available. (Hint: use pkg-config and
+dnl -uninstalled.pc files if available).
+dnl code based on a simplification of _AC_OUTPUT_SUBDIRS in 
+dnl /usr/share/autoconf/autoconf/status.m4 which implements part of 
+dnl AC_CONFIG_SUBDIRS
+
+AC_DEFUN([AX_CONFIG_DIR],
+[AC_REQUIRE([AC_DISABLE_OPTION_CHECKING])]
+[m4_append([_AC_LIST_SUBDIRS], [$1], [])]
+[
+  # Remove --cache-file and --srcdir arguments so they do not pile up.
+  ax_sub_configure_args=
+  ax_prev=
+  eval "set x $ac_configure_args"
+  shift
+  for ax_arg
+  do
+    if test -n "$ax_prev"; then
+      ax_prev=
+      continue
+    fi
+    case $ax_arg in
+    -cache-file | --cache-file | --cache-fil | --cache-fi \
+    | --cache-f | --cache- | --cache | --cach | --cac | --ca | --c)
+      ax_prev=cache_file ;;
+    -cache-file=* | --cache-file=* | --cache-fil=* | --cache-fi=* \
+    | --cache-f=* | --cache-=* | --cache=* | --cach=* | --cac=* | --ca=* \
+    | --c=*)
+      ;;
+    --config-cache | -C)
+      ;;
+    -srcdir | --srcdir | --srcdi | --srcd | --src | --sr)
+      ax_prev=srcdir ;;
+    -srcdir=* | --srcdir=* | --srcdi=* | --srcd=* | --src=* | --sr=*)
+      ;;
+    -prefix | --prefix | --prefi | --pref | --pre | --pr | --p)
+      ax_prev=prefix ;;
+    -prefix=* | --prefix=* | --prefi=* | --pref=* | --pre=* | --pr=* | --p=*)
+      ;;
+    *)
+      case $ax_arg in
+      *\'*) ax_arg=`echo "$ax_arg" | sed "s/'/'\\\\\\\\''/g"` ;;
+      esac
+      ax_sub_configure_args="$ax_sub_configure_args '$ax_arg'" ;;
+    esac
+  done
+
+  # Always prepend --prefix to ensure using the same prefix
+  # in subdir configurations.
+  ax_arg="--prefix=$prefix"
+  case $ax_arg in
+  *\'*) ax_arg=`echo "$ax_arg" | sed "s/'/'\\\\\\\\''/g"` ;;
+  esac
+  ax_sub_configure_args="'$ax_arg' $ax_sub_configure_args"
+
+  # Pass --silent
+  if test "$silent" = yes; then
+    ax_sub_configure_args="--silent $ax_sub_configure_args"
+  fi
+
+  ax_popdir=`pwd`
+  AC_MSG_NOTICE([Configuring sources in $1])
+  dnl for out-of-place builds srcdir and builddir will be different, and
+  dnl builddir may not exist, so we must create it
+  AS_MKDIR_P(["$1"])
+  dnl and also set the variables. As this isn't autoconf, the following may be
+  dnl risky:
+  _AC_SRCDIRS(["$1"])
+  cd "$1"
+
+  # Check for guested configure; otherwise get Cygnus style configure.
+  if test -f "configure.gnu"; then
+    ax_sub_configure=$ac_srcdir/configure.gnu
+  elif test -f "$ac_srcdir/configure"; then
+    ax_sub_configure=$ac_srcdir/configure
+  elif test -f "$ac_srcdir/configure.in"; then
+    # This should be Cygnus configure.
+       ax_sub_configure=$ac_aux_dir/configure
+  else
+    AC_MSG_WARN([no configuration information is in $1])
+    ax_sub_configure=
+  fi
+
+  # The recursion is here.
+  if test -n "$ax_sub_configure"; then
+    # Make the cache file name correct relative to the subdirectory.
+    case $cache_file in
+    [[\\/]]* | ?:[[\\/]]* ) ax_sub_cache_file=$cache_file ;;
+    *) # Relative name.
+       ax_sub_cache_file=$ac_top_build_prefix$cache_file ;;
+    esac
+
+    AC_MSG_NOTICE([running $SHELL $ax_sub_configure $ax_sub_configure_args --cache-file=$ax_sub_cache_file 
--srcdir=$ac_srcdir])
+    # The eval makes quoting arguments work.
+    eval "\$SHELL \"\$ax_sub_configure\" $ax_sub_configure_args \
+          --cache-file=\"\$ax_sub_cache_file\" --srcdir=\"\$ax_srcdir\""
+  fi
+
+  cd "$ax_popdir"
+  AC_MSG_NOTICE([Done configuring in $1])
+])
+
diff --git a/src/Makefile.am b/src/Makefile.am
index 213e8ae..79cba81 100644
--- a/src/Makefile.am
+++ b/src/Makefile.am
@@ -73,6 +73,7 @@ AM_CPPFLAGS = \
        $(GTK_CFLAGS) \
        $(TP_GLIB_CFLAGS) \
        $(TP_LOGGER_CFLAGS) \
+       $(TPAW_CFLAGS) \
        $(WARN_CFLAGS) \
        $(NULL)
 
@@ -84,6 +85,7 @@ gnome_chat_LDADD = \
        $(GTK_LIBS) \
        $(TP_GLIB_LIBS) \
        $(TP_LOGGER_LIBS) \
+       $(TPAW_LIBS) \
        $(NULL)
 
 CLEANFILES = \
diff --git a/telepathy-account-widgets b/telepathy-account-widgets
new file mode 160000
index 0000000..a103209
--- /dev/null
+++ b/telepathy-account-widgets
@@ -0,0 +1 @@
+Subproject commit a103209ee93d5f59730752426e207046fa3dba13
[Date Prev][Date Next]   [Thread Prev][Thread Next]   [Thread Index] [Date Index] [Author Index]