[bijiben] eggListBox : import as a git submodule

[Pierre-Yves Luyten <pyluyten src gnome org>]

commit 286c01599b3ac8edc82dde5a649a7d409afb6491
Author: Pierre-Yves Luyten <py luyten fr>
Date:   Tue May 14 01:10:03 2013 +0200

    eggListBox : import as a git submodule

 .gitmodules         |    3 +
 Makefile.am         |    2 +-
 autogen.sh          |    7 +++
 configure.ac        |   34 ++++++++++++++--
 egg-list-box        |    1 +
 m4/ax_config_dir.m4 |  109 +++++++++++++++++++++++++++++++++++++++++++++++++++
 po/POTFILES.skip    |    1 +
 7 files changed, 152 insertions(+), 5 deletions(-)
---
diff --git a/.gitmodules b/.gitmodules
index bfd964e..ee3430a 100644
--- a/.gitmodules
+++ b/.gitmodules
@@ -1,3 +1,6 @@
 [submodule "libgd"]
        path = libgd
        url = git://git.gnome.org/libgd
+[submodule "egg-list-box"]
+       path = egg-list-box
+       url = git://git.gnome.org/egg-list-box
diff --git a/Makefile.am b/Makefile.am
index 58879ac..3ffbfaa 100644
--- a/Makefile.am
+++ b/Makefile.am
@@ -1,6 +1,6 @@
 ACLOCAL_AMFLAGS = -I m4 -I libgd ${ACLOCAL_FLAGS}
 
-SUBDIRS = libgd src data po help
+SUBDIRS = egg-list-box libgd src data po help
 
 bijibendoc = \
        README\
diff --git a/autogen.sh b/autogen.sh
index 898f955..6bb9a7e 100755
--- a/autogen.sh
+++ b/autogen.sh
@@ -21,4 +21,11 @@ which gnome-autogen.sh || {
 
 git submodule update --init --recursive
 
+# egg-list-box
+
+cd egg-list-box
+sh autogen.sh --no-configure
+cd ..
+
+
 REQUIRED_AUTOMAKE_VERSION=1.9 . gnome-autogen.sh
diff --git a/configure.ac b/configure.ac
index d336b51..758b8bf 100644
--- a/configure.ac
+++ b/configure.ac
@@ -35,11 +35,37 @@ IT_PROG_INTLTOOL([0.35.0])
 AM_PROG_LIBTOOL
 
 
-dnl tracker-sparql might be 0.12
 
-PKG_CHECK_MODULES(BIJIBEN, tracker-sparql-0.16 clutter-gtk-1.0
-[gtk+-3.0 >= 3.7.7 libxml-2.0 glib-2.0 zeitgeist-1.0
- glib-2.0 >= 2.28 gio-unix-2.0 webkitgtk-3.0 uuid])
+# EggListBox submodule
+prev_top_build_prefix=$ac_top_build_prefix
+prev_ac_configure_args=$ac_configure_args
+AX_CONFIG_DIR([egg-list-box])
+ac_top_build_prefix=$prev_top_build_prefix
+ac_configure_args=$prev_ac_configure_args
+
+export PKG_CONFIG_PATH=$PKG_CONFIG_PATH:"$ac_top_build_prefix"egg-list-box
+
+
+
+
+
+GLIB_REQUIRED_VERSION=2.28
+GTK_REQUIRED_VERSION=3.7.7
+
+
+PKG_CHECK_MODULES(BIJIBEN,
+                  [ clutter-gtk-1.0
+                    egg-list-box
+                    gio-unix-2.0
+                    glib-2.0 >= $GLIB_REQUIRED_VERSION
+                    gtk+-3.0 >= $GTK_REQUIRED_VERSION
+                    libxml-2.0
+                    tracker-sparql-0.16
+                    uuid
+                    webkitgtk-3.0
+                    zeitgeist-1.0])
+
+
 
 GLIB_GSETTINGS
 
diff --git a/egg-list-box b/egg-list-box
new file mode 160000
index 0000000..6100672
--- /dev/null
+++ b/egg-list-box
@@ -0,0 +1 @@
+Subproject commit 610067298101999284eb7ee25f3fb4eca2eb72dd
diff --git a/m4/ax_config_dir.m4 b/m4/ax_config_dir.m4
new file mode 100644
index 0000000..0ba313f
--- /dev/null
+++ b/m4/ax_config_dir.m4
@@ -0,0 +1,109 @@
+dnl Copied from Audacity 1.3.10 which itself is licensed under the GPL v2 or
+dnl any later version
+
+dnl Function to configure a sub-library now, because we need to know the result
+dnl of the configuration now in order to take decisions.
+dnl We don't worry about whether the configuration worked or not - it is
+dnl assumed that the next thing after this will be a package-specific check to
+dnl see if the package is actually available. (Hint: use pkg-config and
+dnl -uninstalled.pc files if available).
+dnl code based on a simplification of _AC_OUTPUT_SUBDIRS in 
+dnl /usr/share/autoconf/autoconf/status.m4 which implements part of 
+dnl AC_CONFIG_SUBDIRS
+
+AC_DEFUN([AX_CONFIG_DIR],
+[AC_REQUIRE([AC_DISABLE_OPTION_CHECKING])]
+[m4_append([_AC_LIST_SUBDIRS], [$1], [])]
+[
+  # Remove --cache-file and --srcdir arguments so they do not pile up.
+  ax_sub_configure_args=
+  ax_prev=
+  eval "set x $ac_configure_args"
+  shift
+  for ax_arg
+  do
+    if test -n "$ax_prev"; then
+      ax_prev=
+      continue
+    fi
+    case $ax_arg in
+    -cache-file | --cache-file | --cache-fil | --cache-fi \
+    | --cache-f | --cache- | --cache | --cach | --cac | --ca | --c)
+      ax_prev=cache_file ;;
+    -cache-file=* | --cache-file=* | --cache-fil=* | --cache-fi=* \
+    | --cache-f=* | --cache-=* | --cache=* | --cach=* | --cac=* | --ca=* \
+    | --c=*)
+      ;;
+    --config-cache | -C)
+      ;;
+    -srcdir | --srcdir | --srcdi | --srcd | --src | --sr)
+      ax_prev=srcdir ;;
+    -srcdir=* | --srcdir=* | --srcdi=* | --srcd=* | --src=* | --sr=*)
+      ;;
+    -prefix | --prefix | --prefi | --pref | --pre | --pr | --p)
+      ax_prev=prefix ;;
+    -prefix=* | --prefix=* | --prefi=* | --pref=* | --pre=* | --pr=* | --p=*)
+      ;;
+    *)
+      case $ax_arg in
+      *\'*) ax_arg=`echo "$ax_arg" | sed "s/'/'\\\\\\\\''/g"` ;;
+      esac
+      ax_sub_configure_args="$ax_sub_configure_args '$ax_arg'" ;;
+    esac
+  done
+
+  # Always prepend --prefix to ensure using the same prefix
+  # in subdir configurations.
+  ax_arg="--prefix=$prefix"
+  case $ax_arg in
+  *\'*) ax_arg=`echo "$ax_arg" | sed "s/'/'\\\\\\\\''/g"` ;;
+  esac
+  ax_sub_configure_args="'$ax_arg' $ax_sub_configure_args"
+
+  # Pass --silent
+  if test "$silent" = yes; then
+    ax_sub_configure_args="--silent $ax_sub_configure_args"
+  fi
+
+  ax_popdir=`pwd`
+  AC_MSG_NOTICE([Configuring sources in $1])
+  dnl for out-of-place builds srcdir and builddir will be different, and
+  dnl builddir may not exist, so we must create it
+  AS_MKDIR_P(["$1"])
+  dnl and also set the variables. As this isn't autoconf, the following may be
+  dnl risky:
+  _AC_SRCDIRS(["$1"])
+  cd "$1"
+
+  # Check for guested configure; otherwise get Cygnus style configure.
+  if test -f "configure.gnu"; then
+    ax_sub_configure=$ac_srcdir/configure.gnu
+  elif test -f "$ac_srcdir/configure"; then
+    ax_sub_configure=$ac_srcdir/configure
+  elif test -f "$ac_srcdir/configure.in"; then
+    # This should be Cygnus configure.
+       ax_sub_configure=$ac_aux_dir/configure
+  else
+    AC_MSG_WARN([no configuration information is in $1])
+    ax_sub_configure=
+  fi
+
+  # The recursion is here.
+  if test -n "$ax_sub_configure"; then
+    # Make the cache file name correct relative to the subdirectory.
+    case $cache_file in
+    [[\\/]]* | ?:[[\\/]]* ) ax_sub_cache_file=$cache_file ;;
+    *) # Relative name.
+       ax_sub_cache_file=$ac_top_build_prefix$cache_file ;;
+    esac
+
+    AC_MSG_NOTICE([running $SHELL $ax_sub_configure $ax_sub_configure_args --cache-file=$ax_sub_cache_file 
--srcdir=$ac_srcdir])
+    # The eval makes quoting arguments work.
+    eval "\$SHELL \"\$ax_sub_configure\" $ax_sub_configure_args \
+          --cache-file=\"\$ax_sub_cache_file\" --srcdir=\"\$ax_srcdir\""
+  fi
+
+  cd "$ax_popdir"
+  AC_MSG_NOTICE([Done configuring in $1])
+])
+
diff --git a/po/POTFILES.skip b/po/POTFILES.skip
index aa95c49..1492519 100644
--- a/po/POTFILES.skip
+++ b/po/POTFILES.skip
@@ -1,2 +1,3 @@
+egg-list-box/egg-flow-box.c
 data/bijiben.desktop.in
 libgd/libgd/gd-header-bar.c