[latexila] Minimal Autotools build system

[SÃbastien Wilmet <swilmet src gnome org>]

commit 3e636f0acc93d59964def6f6954a9ae370e02e26
Author: SÃbastien Wilmet <swilmet gnome org>
Date:   Wed Aug 29 15:26:13 2012 +0200

    Minimal Autotools build system

 Makefile.am     |    1 +
 configure.ac    |   79 +++++++++++++++++++++++++++++++++++++++++++++++++++++++
 src/.gitignore  |    1 +
 src/Makefile.am |   70 ++++++++++++++++++++++++++++++++++++++++++++++++
 4 files changed, 151 insertions(+), 0 deletions(-)
---
diff --git a/Makefile.am b/Makefile.am
new file mode 100644
index 0000000..af437a6
--- /dev/null
+++ b/Makefile.am
@@ -0,0 +1 @@
+SUBDIRS = src
diff --git a/configure.ac b/configure.ac
new file mode 100644
index 0000000..50f638e
--- /dev/null
+++ b/configure.ac
@@ -0,0 +1,79 @@
+#                                               -*- Autoconf -*-
+# Process this file with autoconf to produce a configure script.
+
+# Init Autoconf
+AC_PREREQ([2.64])
+
+AC_INIT([LaTeXila],
+        [2.5.3],
+        [https://bugzilla.gnome.org/enter_bug.cgi?product=latexila],
+	[latexila],
+	[http://projects.gnome.org/latexila])
+
+AC_CONFIG_SRCDIR([src/latexila.vala])
+AC_CONFIG_HEADERS([config.h])
+AC_CONFIG_MACRO_DIR([m4])
+
+# Init Automake
+AM_INIT_AUTOMAKE([1.11 foreign tar-ustar no-dist-gzip dist-xz])
+AM_MAINTAINER_MODE([enable])
+AM_SILENT_RULES([yes])
+
+# Required dependencies versions
+GLIB_REQUIRED_VERSION="2.32"
+GTK_REQUIRED_VERSION="3.4.3"
+GTKSOURCEVIEW_REQUIRED_VERSION="3.4.1"
+GTKSPELL_REQUIRED_VERSION="3.0"
+VALA_REQUIRED_VERSION="0.17.3.1"
+
+AC_SUBST([GLIB_REQUIRED_VERSION])
+AC_SUBST([GTK_REQUIRED_VERSION])
+AC_SUBST([GTKSOURCEVIEW_REQUIRED_VERSION])
+AC_SUBST([GTKSPELL_REQUIRED_VERSION])
+AC_SUBST([VALA_REQUIRED_VERSION])
+
+# Checks for programs
+AC_PROG_CC
+AC_PROG_INSTALL
+AM_PROG_VALAC([${VALA_REQUIRED_VERSION}])
+AC_PATH_PROG([GLIB_COMPILE_RESOURCES], [glib-compile-resources])
+
+# Checks for dependencies
+PKG_CHECK_MODULES([LATEXILA], [
+	glib-2.0 >= ${GLIB_REQUIRED_VERSION}
+	gio-2.0 >= ${GLIB_REQUIRED_VERSION}
+	gtk+-3.0 >= ${GTK_REQUIRED_VERSION}
+	gtksourceview-3.0 >= ${GTKSOURCEVIEW_REQUIRED_VERSION}
+	gsettings-desktop-schemas
+	gee-1.0
+	gtkspell-3.0
+])
+
+AC_SUBST([LATEXILA_CFLAGS])
+AC_SUBST([LATEXILA_LIBS])
+
+# Native Language Support
+GETTEXT_PACKAGE="latexila"
+AC_SUBST([GETTEXT_PACKAGE])
+
+# GSettings
+GLIB_GSETTINGS
+
+# Generate files
+AC_CONFIG_FILES([Makefile
+                 src/Makefile
+                 README
+		 INSTALL])
+
+AC_OUTPUT
+
+# Print a summary of the configuration
+echo "
+
+Configuration:
+
+    ${PACKAGE_NAME} version ${PACKAGE_VERSION}
+
+    Prefix: ${prefix}
+    Compiler: ${CC} ${CFLAGS} ${CPPFLAGS}
+"
diff --git a/src/.gitignore b/src/.gitignore
new file mode 100644
index 0000000..064a8d8
--- /dev/null
+++ b/src/.gitignore
@@ -0,0 +1 @@
+*.c
diff --git a/src/Makefile.am b/src/Makefile.am
new file mode 100644
index 0000000..9447f6a
--- /dev/null
+++ b/src/Makefile.am
@@ -0,0 +1,70 @@
+bin_PROGRAMS = latexila
+
+VALAFLAGS =			\
+	--pkg gtk+-3.0		\
+	--pkg gtksourceview-3.0	\
+	--pkg gee-1.0		\
+	--pkg posix
+
+# The valac command is always executed in the sources directory, not the build
+# directory. If $(top_srcdir) is used, it will be relative to the build directory.
+vapidir = ../vapi
+
+latexila_SOURCES = 			\
+	app_settings.vala		\
+	bottom_panel.vala		\
+	build_command_runner.vala	\
+	build_job_runner.vala		\
+	build_tool_dialog.vala		\
+	build_tool_runner.vala		\
+	build_tools_preferences.vala	\
+	build_tools.vala		\
+	build_view.vala			\
+	clean_build_files.vala		\
+	completion.vala			\
+	custom_statusbar.vala		\
+	dialogs.vala			\
+	documents_panel.vala		\
+	document_structure.vala		\
+	document_tab.vala		\
+	document.vala			\
+	document_view.vala		\
+	encodings.vala			\
+	error_entry.vala		\
+	file_browser.vala		\
+	gedit/gedit-close-button.c	\
+	gedit/gedit-close-button.h	\
+	latexila.vala			\
+	latex_menu.vala			\
+	latex_post_processor.vala	\
+	main.vala			\
+	main_window_build_tools.vala	\
+	main_window_documents.vala	\
+	main_window_edit.vala		\
+	main_window_file.vala		\
+	main_window_structure.vala	\
+	main_window.vala		\
+	menu_in_toolbar.vala		\
+	most_used_symbols.vala		\
+	post_processors.vala		\
+	preferences_dialog.vala		\
+	project_dialogs.vala		\
+	projects.vala			\
+	search.vala			\
+	side_panel.vala			\
+	stock_icons.vala		\
+	structure_model.vala		\
+	structure.vala			\
+	symbols.vala			\
+	symbols_view.vala		\
+	tab_info_bar.vala		\
+	templates_dialogs.vala		\
+	templates.vala			\
+	utils.vala			\
+	$(vapidir)/config.vapi		\
+	$(vapidir)/gedit.vapi		\
+	$(vapidir)/gtkspell-2.0.vapi	\
+	$(vapidir)/menu_tool_action.vapi
+
+latexila_CPPFLAGS = -I$(top_srcdir) $(LATEXILA_CFLAGS)
+latexila_LDFLAGS = $(LATEXILA_LIBS)