[gnome-initial-setup] Import egg-list-box

[Jasper St. Pierre <jstpierre src gnome org>]

commit a37be4fd661d6762e0da8a1a7a0fef9952ba1e80
Author: Jasper St. Pierre <jstpierre mecheye net>
Date:   Mon Nov 19 17:41:26 2012 -0500

    Import egg-list-box

 .gitignore          |    1 -
 .gitmodules         |    3 +
 Makefile.am         |    2 +-
 autogen.sh          |   12 ++++++
 configure.ac        |    9 ++++
 egg-list-box        |    1 +
 m4/.gitignore       |   36 +++++++++++++++++
 m4/ax_config_dir.m4 |  109 +++++++++++++++++++++++++++++++++++++++++++++++++++
 8 files changed, 171 insertions(+), 2 deletions(-)
---
diff --git a/.gitignore b/.gitignore
index 431f6e2..225ef74 100644
--- a/.gitignore
+++ b/.gitignore
@@ -29,7 +29,6 @@ help/*.omf
 install-sh
 libtool
 ltmain.sh
-m4/
 missing
 mkinstalldirs
 po/*.gmo
diff --git a/.gitmodules b/.gitmodules
new file mode 100644
index 0000000..992c00b
--- /dev/null
+++ b/.gitmodules
@@ -0,0 +1,3 @@
+[submodule "egg-list-box"]
+	path = egg-list-box
+	url = git://git.gnome.org/egg-list-box
diff --git a/Makefile.am b/Makefile.am
index 6659654..bc0cacb 100644
--- a/Makefile.am
+++ b/Makefile.am
@@ -2,7 +2,7 @@
 ACLOCAL_AMFLAGS = -I m4 ${ACLOCAL_FLAGS}
 AM_CFLAGS = ${WARN_CFLAGS}
 
-SUBDIRS = data gnome-initial-setup player po
+SUBDIRS = data gnome-initial-setup player po egg-list-box
 
 EXTRA_DIST = \
     autogen.sh \
diff --git a/autogen.sh b/autogen.sh
index 4865b47..d45011e 100755
--- a/autogen.sh
+++ b/autogen.sh
@@ -16,6 +16,18 @@ PKG_NAME="gnome-initial-setup"
     exit 1
 }
 
+# Fetch submodules if needed
+if test ! -f egg-list-box/COPYING;
+then
+  echo "+ Setting up submodules"
+  git submodule init
+fi
+git submodule update
+
+cd egg-list-box
+sh autogen.sh --no-configure
+cd ..
+
 which gnome-autogen.sh || {
     echo "You need to install gnome-common"
     exit 1
diff --git a/configure.ac b/configure.ac
index 8080c9e..40f708f 100644
--- a/configure.ac
+++ b/configure.ac
@@ -19,6 +19,15 @@ GLIB_REQUIRED_VERSION=2.29.4
 GTK_REQUIRED_VERSION=3.1.2
 CLUTTER_REQUIRED_VERSION=1.11.3
 
+# EggListBox submodule
+prev_top_build_prefix=$ac_top_build_prefix
+prev_ac_configure_args=$ac_configure_args
+AX_CONFIG_DIR([egg-list-box])
+ac_top_build_prefix=$prev_top_build_prefix
+ac_configure_args=$prev_ac_configure_args
+
+export PKG_CONFIG_PATH=$PKG_CONFIG_PATH:"$ac_top_build_prefix"egg-list-box
+
 PKG_CHECK_MODULES(INITIAL_SETUP,
                   NetworkManager >= $NETWORK_MANAGER_REQUIRED_VERSION
                   libnm-glib >= $NETWORK_MANAGER_REQUIRED_VERSION
diff --git a/egg-list-box b/egg-list-box
new file mode 160000
index 0000000..b32d127
--- /dev/null
+++ b/egg-list-box
@@ -0,0 +1 @@
+Subproject commit b32d1270655f7c6c83550ae1adc0934105c0cc00
diff --git a/m4/.gitignore b/m4/.gitignore
new file mode 100644
index 0000000..17d186b
--- /dev/null
+++ b/m4/.gitignore
@@ -0,0 +1,36 @@
+gtk-doc.m4
+intltool.m4
+libtool.m4
+ltoptions.m4
+ltsugar.m4
+ltversion.m4
+lt~obsolete.m4
+codeset.m4
+gettext.m4
+glibc2.m4
+glibc21.m4
+iconv.m4
+intdiv0.m4
+intl.m4
+intldir.m4
+intlmacosx.m4
+intmax.m4
+inttypes-pri.m4
+inttypes_h.m4
+lcmessage.m4
+lib-ld.m4
+lib-link.m4
+lib-prefix.m4
+lock.m4
+longlong.m4
+nls.m4
+po.m4
+printf-posix.m4
+progtest.m4
+size_max.m4
+stdint_h.m4
+uintmax_t.m4
+visibility.m4
+wchar_t.m4
+wint_t.m4
+xsize.m4
diff --git a/m4/ax_config_dir.m4 b/m4/ax_config_dir.m4
new file mode 100644
index 0000000..0ba313f
--- /dev/null
+++ b/m4/ax_config_dir.m4
@@ -0,0 +1,109 @@
+dnl Copied from Audacity 1.3.10 which itself is licensed under the GPL v2 or
+dnl any later version
+
+dnl Function to configure a sub-library now, because we need to know the result
+dnl of the configuration now in order to take decisions.
+dnl We don't worry about whether the configuration worked or not - it is
+dnl assumed that the next thing after this will be a package-specific check to
+dnl see if the package is actually available. (Hint: use pkg-config and
+dnl -uninstalled.pc files if available).
+dnl code based on a simplification of _AC_OUTPUT_SUBDIRS in 
+dnl /usr/share/autoconf/autoconf/status.m4 which implements part of 
+dnl AC_CONFIG_SUBDIRS
+
+AC_DEFUN([AX_CONFIG_DIR],
+[AC_REQUIRE([AC_DISABLE_OPTION_CHECKING])]
+[m4_append([_AC_LIST_SUBDIRS], [$1], [])]
+[
+  # Remove --cache-file and --srcdir arguments so they do not pile up.
+  ax_sub_configure_args=
+  ax_prev=
+  eval "set x $ac_configure_args"
+  shift
+  for ax_arg
+  do
+    if test -n "$ax_prev"; then
+      ax_prev=
+      continue
+    fi
+    case $ax_arg in
+    -cache-file | --cache-file | --cache-fil | --cache-fi \
+    | --cache-f | --cache- | --cache | --cach | --cac | --ca | --c)
+      ax_prev=cache_file ;;
+    -cache-file=* | --cache-file=* | --cache-fil=* | --cache-fi=* \
+    | --cache-f=* | --cache-=* | --cache=* | --cach=* | --cac=* | --ca=* \
+    | --c=*)
+      ;;
+    --config-cache | -C)
+      ;;
+    -srcdir | --srcdir | --srcdi | --srcd | --src | --sr)
+      ax_prev=srcdir ;;
+    -srcdir=* | --srcdir=* | --srcdi=* | --srcd=* | --src=* | --sr=*)
+      ;;
+    -prefix | --prefix | --prefi | --pref | --pre | --pr | --p)
+      ax_prev=prefix ;;
+    -prefix=* | --prefix=* | --prefi=* | --pref=* | --pre=* | --pr=* | --p=*)
+      ;;
+    *)
+      case $ax_arg in
+      *\'*) ax_arg=`echo "$ax_arg" | sed "s/'/'\\\\\\\\''/g"` ;;
+      esac
+      ax_sub_configure_args="$ax_sub_configure_args '$ax_arg'" ;;
+    esac
+  done
+
+  # Always prepend --prefix to ensure using the same prefix
+  # in subdir configurations.
+  ax_arg="--prefix=$prefix"
+  case $ax_arg in
+  *\'*) ax_arg=`echo "$ax_arg" | sed "s/'/'\\\\\\\\''/g"` ;;
+  esac
+  ax_sub_configure_args="'$ax_arg' $ax_sub_configure_args"
+
+  # Pass --silent
+  if test "$silent" = yes; then
+    ax_sub_configure_args="--silent $ax_sub_configure_args"
+  fi
+
+  ax_popdir=`pwd`
+  AC_MSG_NOTICE([Configuring sources in $1])
+  dnl for out-of-place builds srcdir and builddir will be different, and
+  dnl builddir may not exist, so we must create it
+  AS_MKDIR_P(["$1"])
+  dnl and also set the variables. As this isn't autoconf, the following may be
+  dnl risky:
+  _AC_SRCDIRS(["$1"])
+  cd "$1"
+
+  # Check for guested configure; otherwise get Cygnus style configure.
+  if test -f "configure.gnu"; then
+    ax_sub_configure=$ac_srcdir/configure.gnu
+  elif test -f "$ac_srcdir/configure"; then
+    ax_sub_configure=$ac_srcdir/configure
+  elif test -f "$ac_srcdir/configure.in"; then
+    # This should be Cygnus configure.
+	ax_sub_configure=$ac_aux_dir/configure
+  else
+    AC_MSG_WARN([no configuration information is in $1])
+    ax_sub_configure=
+  fi
+
+  # The recursion is here.
+  if test -n "$ax_sub_configure"; then
+    # Make the cache file name correct relative to the subdirectory.
+    case $cache_file in
+    [[\\/]]* | ?:[[\\/]]* ) ax_sub_cache_file=$cache_file ;;
+    *) # Relative name.
+	ax_sub_cache_file=$ac_top_build_prefix$cache_file ;;
+    esac
+
+    AC_MSG_NOTICE([running $SHELL $ax_sub_configure $ax_sub_configure_args --cache-file=$ax_sub_cache_file --srcdir=$ac_srcdir])
+    # The eval makes quoting arguments work.
+    eval "\$SHELL \"\$ax_sub_configure\" $ax_sub_configure_args \
+	   --cache-file=\"\$ax_sub_cache_file\" --srcdir=\"\$ax_srcdir\""
+  fi
+
+  cd "$ax_popdir"
+  AC_MSG_NOTICE([Done configuring in $1])
+])
+