GNOME.org
 

[gtk-vnc] Import GNULIBs GCC warning module

commit 5fbe696479cb8813f77a536a9559dd80dd58299f
Author: Daniel P. Berrange <berrange redhat com>
Date:   Fri Feb 10 17:02:31 2012 +0000

    Import GNULIBs GCC warning module
    
    Replace hand-written warning checks with GNULIB module

 acinclude.m4           |  138 ------------------------------------
 m4/gtk-vnc-warnings.m4 |  111 +++++++++++++++++++++++++++++
 m4/manywarnings.m4     |  184 ++++++++++++++++++++++++++++++++++++++++++++++++
 m4/warnings.m4         |   37 ++++++++++
 src/Makefile.am        |    8 +-
 5 files changed, 336 insertions(+), 142 deletions(-)
---
diff --git a/acinclude.m4 b/acinclude.m4
index 7b4129a..a25827e 100644
--- a/acinclude.m4
+++ b/acinclude.m4
@@ -1,141 +1,3 @@
-# serial 3
-# Find valid warning flags for the C Compiler.           -*-Autoconf-*-
-#
-# Copyright (C) 2001, 2002, 2006 Free Software Foundation, Inc.
-#
-# This program is free software; you can redistribute it and/or modify
-# it under the terms of the GNU General Public License as published by
-# the Free Software Foundation; either version 2 of the License, or
-# (at your option) any later version.
-#
-# This program is distributed in the hope that it will be useful,
-# but WITHOUT ANY WARRANTY; without even the implied warranty of
-# MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
-# GNU General Public License for more details.
-#
-# You should have received a copy of the GNU General Public License
-# along with this program; if not, write to the Free Software
-# Foundation, Inc., 51 Franklin Street, Fifth Floor, Boston, MA
-# 02110-1301  USA
-
-# Written by Jesse Thilo.
-
-AC_DEFUN([gl_COMPILER_FLAGS],
-  [AC_MSG_CHECKING(whether compiler accepts $1)
-   AC_SUBST(COMPILER_FLAGS)
-   ac_save_CFLAGS="$CFLAGS"
-   dnl Some flags are dependant, so we set all previously checked
-   dnl flags when testing. Except for -Werror which we have to
-   dnl check on its own, because some of our compiler flags cause
-   dnl warnings from the autoconf test program!
-   if test "$1" = "-Werror" ; then
-     CFLAGS="$CFLAGS $1"
-   else
-     CFLAGS="$CFLAGS $COMPILER_FLAGS $1"
-   fi
-   AC_TRY_LINK([], [], has_option=yes, has_option=no,)
-   echo 'int x;' >conftest.c
-   $CC $CFLAGS -c conftest.c 2>conftest.err
-   ret=$?
-   if test $ret != 0 || test -s conftest.err || test $has_option = "no"; then
-       AC_MSG_RESULT(no)
-   else
-       AC_MSG_RESULT(yes)
-       COMPILER_FLAGS="$COMPILER_FLAGS $1"
-   fi
-   CFLAGS="$ac_save_CFLAGS"
-   rm -f conftest*
- ])
-
-
-dnl
-dnl Taken from gnome-common/macros2/gnome-compiler-flags.m4
-dnl
-dnl We've added:
-dnl   -Wextra -Wshadow -Wcast-align -Wwrite-strings -Waggregate-return -Wstrict-prototypes -Winline -Wredundant-decls
-dnl We've removed
-dnl   CFLAGS="$realsave_CFLAGS"
-dnl   to avoid clobbering user-specified CFLAGS
-dnl
-AC_DEFUN([GTK_VNC_COMPILE_WARNINGS],[
-    dnl ******************************
-    dnl More compiler warnings
-    dnl ******************************
-
-    AC_ARG_ENABLE(compile-warnings,
-                  AC_HELP_STRING([--enable-compile-warnings=@<:@no/minimum/yes/maximum/error@:>@],
-                                 [Turn on compiler warnings]),,
-                  [enable_compile_warnings="m4_default([$1],[maximum])"])
-
-    warnCFLAGS=
-
-    common_flags="-Wp,-D_FORTIFY_SOURCE=2 -fexceptions -fasynchronous-unwind-tables"
-
-    case "$enable_compile_warnings" in
-    no)
-        try_compiler_flags=""
-	;;
-    minimum)
-	try_compiler_flags="-Wall -Wformat -Wformat-security $common_flags"
-	;;
-    yes)
-	try_compiler_flags="-Wall -Wformat -Wformat-security -Wmissing-prototypes $common_flags"
-	;;
-    maximum|error)
-	try_compiler_flags="-Wall -Wformat -Wformat-security -Wmissing-prototypes -Wnested-externs -Wpointer-arith"
-	try_compiler_flags="$try_compiler_flags -Wextra -Wshadow -Wcast-align -Wwrite-strings -Waggregate-return"
-	dnl XXX disabled strict-prototypes due  to bug in gtk header files
-	dnl /usr/include/gtk-2.0/gtk/gtkitemfactory.h:47: warning: function declaration isnât a prototype
-	dnl try_compiler_flags="$try_compiler_flags -Wstrict-prototypes -Winline -Wredundant-decls -Wno-sign-compare"
-	try_compiler_flags="$try_compiler_flags -Winline -Wredundant-decls -Wno-sign-compare"
-	try_compiler_flags="$try_compiler_flags $common_flags"
-	if test "$enable_compile_warnings" = "error" ; then
-	    try_compiler_flags="$try_compiler_flags -Werror"
-	fi
-	;;
-    *)
-	AC_MSG_ERROR(Unknown argument '$enable_compile_warnings' to --enable-compile-warnings)
-	;;
-    esac
-
-    COMPILER_FLAGS=
-    for option in $try_compiler_flags; do
-        gl_COMPILER_FLAGS($option)
-    done
-    unset option
-    unset try_compiler_flags
-
-    AC_ARG_ENABLE(iso-c,
-                  AC_HELP_STRING([--enable-iso-c],
-                                 [Try to warn if code is not ISO C ]),,
-                  [enable_iso_c=no])
-
-    AC_MSG_CHECKING(what language compliance flags to pass to the C compiler)
-    complCFLAGS=
-    if test "x$enable_iso_c" != "xno"; then
-	if test "x$GCC" = "xyes"; then
-	case " $CFLAGS " in
-	    *[\ \	]-ansi[\ \	]*) ;;
-	    *) complCFLAGS="$complCFLAGS -ansi" ;;
-	esac
-	case " $CFLAGS " in
-	    *[\ \	]-pedantic[\ \	]*) ;;
-	    *) complCFLAGS="$complCFLAGS -pedantic" ;;
-	esac
-	fi
-    fi
-    AC_MSG_RESULT($complCFLAGS)
-
-    WARNING_CFLAGS="$COMPILER_FLAGS $complCFLAGS"
-    AC_SUBST(WARNING_CFLAGS)
-
-    dnl Needed to keep compile quiet on python 2.4
-    COMPILER_FLAGS=
-    gl_COMPILER_FLAGS(-Wno-redundant-decls)
-    WARNING_PYTHON_CFLAGS=$COMPILER_FLAGS
-    AC_SUBST(WARNING_PYTHON_CFLAGS)
-])
-
 
 dnl a macro to check for ability to create python extensions
 dnl  AM_CHECK_PYTHON_HEADERS([ACTION-IF-POSSIBLE], [ACTION-IF-NOT-POSSIBLE])
diff --git a/m4/gtk-vnc-warnings.m4 b/m4/gtk-vnc-warnings.m4
new file mode 100644
index 0000000..b383cad
--- /dev/null
+++ b/m4/gtk-vnc-warnings.m4
@@ -0,0 +1,111 @@
+dnl
+dnl Enable all known GCC compiler warnings, except for those
+dnl we can't yet cope with
+dnl
+AC_DEFUN([GTK_VNC_COMPILE_WARNINGS],[
+    dnl ******************************
+    dnl More compiler warnings
+    dnl ******************************
+
+    AC_ARG_ENABLE([werror],
+                  AS_HELP_STRING([--enable-werror], [Use -Werror (if supported)]),
+                  [set_werror="$enableval"],
+                  [if test -d $srcdir/.git; then
+                     is_git_version=true
+                     set_werror=yes
+                   else
+                     set_werror=no
+                   fi])
+
+    # List of warnings that are not relevant / wanted
+
+    # Don't care about C++ compiler compat
+    dontwarn="$dontwarn -Wc++-compat"
+    dontwarn="$dontwarn -Wabi"
+    dontwarn="$dontwarn -Wdeprecated"
+    # Don't care about ancient C standard compat
+    dontwarn="$dontwarn -Wtraditional"
+    # Don't care about ancient C standard compat
+    dontwarn="$dontwarn -Wtraditional-conversion"
+    # Ignore warnings in /usr/include
+    dontwarn="$dontwarn -Wsystem-headers"
+    # Happy for compiler to add struct padding
+    dontwarn="$dontwarn -Wpadded"
+    # GCC very confused with -O2
+    dontwarn="$dontwarn -Wunreachable-code"
+    # Due to d3des violations
+    dontwarn="$dontwarn -Wstrict-overflow"
+    # Allow vars decl in the middle of blocks
+    dontwarn="$dontwarn -Wdeclaration-after-statement"
+    # Using long long is fine
+    dontwarn="$dontwarn -Wlong-long"
+    # Some code issues
+    dontwarn="$dontwarn -Wunsafe-loop-optimizations"
+    # Flaw in gtkitemfactory.h
+    dontwarn="$dontwarn -Wstrict-prototypes"
+    # Generated vncmarshal.c file :-(
+    dontwarn="$dontwarn -Wunused-macros"
+
+    # Get all possible GCC warnings
+    gl_MANYWARN_ALL_GCC([maybewarn])
+
+    # Remove the ones we don't want, blacklisted earlier
+    gl_MANYWARN_COMPLEMENT([wantwarn], [$maybewarn], [$dontwarn])
+
+    # Check for $CC support of each warning
+    for w in $wantwarn; do
+      gl_WARN_ADD([$w])
+    done
+
+    gl_WARN_ADD([-Wno-sign-conversion])
+    gl_WARN_ADD([-Wno-conversion])
+    gl_WARN_ADD([-Wno-sign-compare])
+
+    # GNULIB expects this to be part of -Wc++-compat, but we turn
+    # that one off, so we need to manually enable this again
+    gl_WARN_ADD([-Wjump-misses-init])
+
+    # This should be < 256 really. Currently we're down to 4096,
+    # but using 1024 bytes sized buffers (mostly for virStrerror)
+    # stops us from going down further
+    gl_WARN_ADD([-Wframe-larger-than=4096])
+
+    # Use improved glibc headers
+    AC_DEFINE([_FORTIFY_SOURCE], [2],
+      [enable compile-time and run-time bounds-checking, and some warnings])
+
+    # Extra special flags
+    dnl -fstack-protector stuff passes gl_WARN_ADD with gcc
+    dnl on Mingw32, but fails when actually used
+    case $host in
+       *-*-linux*)
+       dnl Fedora only uses -fstack-protector, but doesn't seem to
+       dnl be great overhead in adding -fstack-protector-all instead
+       dnl gl_WARN_ADD([-fstack-protector])
+       gl_WARN_ADD([-fstack-protector-all])
+       gl_WARN_ADD([--param=ssp-buffer-size=4])
+       ;;
+    esac
+    gl_WARN_ADD([-fexceptions])
+    gl_WARN_ADD([-fasynchronous-unwind-tables])
+    gl_WARN_ADD([-fdiagnostics-show-option])
+    gl_WARN_ADD([-funit-at-a-time])
+
+    # Need -fipa-pure-const in order to make -Wsuggest-attribute=pure
+    # fire even without -O.
+    gl_WARN_ADD([-fipa-pure-const])
+
+    # We should eventually enable this, but right now there are at
+    # least 75 functions triggering warnings.
+    gl_WARN_ADD([-Wno-suggest-attribute=pure])
+    gl_WARN_ADD([-Wno-suggest-attribute=const])
+
+    if test "$set_werror" = "yes"
+    then
+      gl_WARN_ADD([-Werror])
+    fi
+
+    WARN_LDFLAGS=$WARN_CFLAGS
+    AC_SUBST([WARN_CFLAGS])
+    AC_SUBST([WARN_LDFLAGS])
+])
diff --git a/m4/manywarnings.m4 b/m4/manywarnings.m4
new file mode 100644
index 0000000..fd0e372
--- /dev/null
+++ b/m4/manywarnings.m4
@@ -0,0 +1,184 @@
+# manywarnings.m4 serial 3
+dnl Copyright (C) 2008-2012 Free Software Foundation, Inc.
+dnl This file is free software; the Free Software Foundation
+dnl gives unlimited permission to copy and/or distribute it,
+dnl with or without modifications, as long as this notice is preserved.
+
+dnl From Simon Josefsson
+
+# gl_MANYWARN_COMPLEMENT(OUTVAR, LISTVAR, REMOVEVAR)
+# --------------------------------------------------
+# Copy LISTVAR to OUTVAR except for the entries in REMOVEVAR.
+# Elements separated by whitespace.  In set logic terms, the function
+# does OUTVAR = LISTVAR \ REMOVEVAR.
+AC_DEFUN([gl_MANYWARN_COMPLEMENT],
+[
+  gl_warn_set=
+  set x $2; shift
+  for gl_warn_item
+  do
+    case " $3 " in
+      *" $gl_warn_item "*)
+        ;;
+      *)
+        gl_warn_set="$gl_warn_set $gl_warn_item"
+        ;;
+    esac
+  done
+  $1=$gl_warn_set
+])
+
+# gl_MANYWARN_ALL_GCC(VARIABLE)
+# -----------------------------
+# Add all documented GCC warning parameters to variable VARIABLE.
+# Note that you need to test them using gl_WARN_ADD if you want to
+# make sure your gcc understands it.
+AC_DEFUN([gl_MANYWARN_ALL_GCC],
+[
+  dnl First, check if -Wno-missing-field-initializers is needed.
+  dnl -Wmissing-field-initializers is implied by -W, but that issues
+  dnl warnings with GCC version before 4.7, for the common idiom
+  dnl of initializing types on the stack to zero, using { 0, }
+  AC_REQUIRE([AC_PROG_CC])
+  if test -n "$GCC"; then
+
+    dnl First, check -W -Werror -Wno-missing-field-initializers is supported
+    dnl with the current $CC $CFLAGS $CPPFLAGS.
+    AC_MSG_CHECKING([whether -Wno-missing-field-initializers is supported])
+    AC_CACHE_VAL([gl_cv_cc_nomfi_supported], [
+      gl_save_CFLAGS="$CFLAGS"
+      CFLAGS="$CFLAGS -W -Werror -Wno-missing-field-initializers"
+      AC_COMPILE_IFELSE(
+        [AC_LANG_PROGRAM([[]], [[]])],
+        [gl_cv_cc_nomfi_supported=yes],
+        [gl_cv_cc_nomfi_supported=no])
+      CFLAGS="$gl_save_CFLAGS"])
+    AC_MSG_RESULT([$gl_cv_cc_nomfi_supported])
+
+    if test "$gl_cv_cc_nomfi_supported" = yes; then
+      dnl Now check whether -Wno-missing-field-initializers is needed
+      dnl for the { 0, } construct.
+      AC_MSG_CHECKING([whether -Wno-missing-field-initializers is needed])
+      AC_CACHE_VAL([gl_cv_cc_nomfi_needed], [
+        gl_save_CFLAGS="$CFLAGS"
+        CFLAGS="$CFLAGS -W -Werror"
+        AC_COMPILE_IFELSE(
+          [AC_LANG_PROGRAM(
+             [[void f (void)
+               {
+                 typedef struct { int a; int b; } s_t;
+                 s_t s1 = { 0, };
+               }
+             ]],
+             [[]])],
+          [gl_cv_cc_nomfi_needed=no],
+          [gl_cv_cc_nomfi_needed=yes])
+        CFLAGS="$gl_save_CFLAGS"
+      ])
+      AC_MSG_RESULT([$gl_cv_cc_nomfi_needed])
+    fi
+  fi
+
+  gl_manywarn_set=
+  for gl_manywarn_item in \
+    -Wall \
+    -W \
+    -Wformat-y2k \
+    -Wformat-nonliteral \
+    -Wformat-security \
+    -Winit-self \
+    -Wmissing-include-dirs \
+    -Wswitch-default \
+    -Wswitch-enum \
+    -Wunused \
+    -Wunknown-pragmas \
+    -Wstrict-aliasing \
+    -Wstrict-overflow \
+    -Wsystem-headers \
+    -Wfloat-equal \
+    -Wtraditional \
+    -Wtraditional-conversion \
+    -Wdeclaration-after-statement \
+    -Wundef \
+    -Wshadow \
+    -Wunsafe-loop-optimizations \
+    -Wpointer-arith \
+    -Wbad-function-cast \
+    -Wc++-compat \
+    -Wcast-qual \
+    -Wcast-align \
+    -Wwrite-strings \
+    -Wconversion \
+    -Wsign-conversion \
+    -Wlogical-op \
+    -Waggregate-return \
+    -Wstrict-prototypes \
+    -Wold-style-definition \
+    -Wmissing-prototypes \
+    -Wmissing-declarations \
+    -Wmissing-noreturn \
+    -Wmissing-format-attribute \
+    -Wpacked \
+    -Wpadded \
+    -Wredundant-decls \
+    -Wnested-externs \
+    -Wunreachable-code \
+    -Winline \
+    -Winvalid-pch \
+    -Wlong-long \
+    -Wvla \
+    -Wvolatile-register-var \
+    -Wdisabled-optimization \
+    -Wstack-protector \
+    -Woverlength-strings \
+    -Wbuiltin-macro-redefined \
+    -Wmudflap \
+    -Wpacked-bitfield-compat \
+    -Wsync-nand \
+    ; do
+    gl_manywarn_set="$gl_manywarn_set $gl_manywarn_item"
+  done
+  # The following are not documented in the manual but are included in
+  # output from gcc --help=warnings.
+  for gl_manywarn_item in \
+    -Wattributes \
+    -Wcoverage-mismatch \
+    -Wmultichar \
+    -Wunused-macros \
+    ; do
+    gl_manywarn_set="$gl_manywarn_set $gl_manywarn_item"
+  done
+  # More warnings from gcc 4.6.2 --help=warnings.
+  for gl_manywarn_item in \
+    -Wabi \
+    -Wcpp \
+    -Wdeprecated \
+    -Wdeprecated-declarations \
+    -Wdiv-by-zero \
+    -Wdouble-promotion \
+    -Wendif-labels \
+    -Wextra \
+    -Wformat-contains-nul \
+    -Wformat-extra-args \
+    -Wformat-zero-length \
+    -Wformat=2 \
+    -Wmultichar \
+    -Wnormalized=nfc \
+    -Woverflow \
+    -Wpointer-to-int-cast \
+    -Wpragmas \
+    -Wsuggest-attribute=const \
+    -Wsuggest-attribute=noreturn \
+    -Wsuggest-attribute=pure \
+    -Wtrampolines \
+    ; do
+    gl_manywarn_set="$gl_manywarn_set $gl_manywarn_item"
+  done
+
+  # Disable the missing-field-initializers warning if needed
+  if test "$gl_cv_cc_nomfi_needed" = yes; then
+    gl_manywarn_set="$gl_manywarn_set -Wno-missing-field-initializers"
+  fi
+
+  $1=$gl_manywarn_set
+])
diff --git a/m4/warnings.m4 b/m4/warnings.m4
new file mode 100644
index 0000000..69d05a6
--- /dev/null
+++ b/m4/warnings.m4
@@ -0,0 +1,37 @@
+# warnings.m4 serial 5
+dnl Copyright (C) 2008-2012 Free Software Foundation, Inc.
+dnl This file is free software; the Free Software Foundation
+dnl gives unlimited permission to copy and/or distribute it,
+dnl with or without modifications, as long as this notice is preserved.
+
+dnl From Simon Josefsson
+
+# gl_AS_VAR_APPEND(VAR, VALUE)
+# ----------------------------
+# Provide the functionality of AS_VAR_APPEND if Autoconf does not have it.
+m4_ifdef([AS_VAR_APPEND],
+[m4_copy([AS_VAR_APPEND], [gl_AS_VAR_APPEND])],
+[m4_define([gl_AS_VAR_APPEND],
+[AS_VAR_SET([$1], [AS_VAR_GET([$1])$2])])])
+
+# gl_WARN_ADD(PARAMETER, [VARIABLE = WARN_CFLAGS])
+# ------------------------------------------------
+# Adds parameter to WARN_CFLAGS if the compiler supports it.  For example,
+# gl_WARN_ADD([-Wparentheses]).
+AC_DEFUN([gl_WARN_ADD],
+dnl FIXME: gl_Warn must be used unquoted until we can assume
+dnl autoconf 2.64 or newer.
+[AS_VAR_PUSHDEF([gl_Warn], [gl_cv_warn_$1])dnl
+AC_CACHE_CHECK([whether compiler handles $1], m4_defn([gl_Warn]), [
+  gl_save_CPPFLAGS="$CPPFLAGS"
+  CPPFLAGS="${CPPFLAGS} $1"
+  AC_PREPROC_IFELSE([AC_LANG_PROGRAM([])],
+                    [AS_VAR_SET(gl_Warn, [yes])],
+                    [AS_VAR_SET(gl_Warn, [no])])
+  CPPFLAGS="$gl_save_CPPFLAGS"
+])
+AS_VAR_IF(gl_Warn, [yes],
+  [gl_AS_VAR_APPEND(m4_if([$2], [], [[WARN_CFLAGS]], [[$2]]), [" $1"])])
+AS_VAR_POPDEF([gl_Warn])dnl
+m4_ifval([$2], [AS_LITERAL_IF([$2], [AC_SUBST([$2])], [])])dnl
+])
diff --git a/src/Makefile.am b/src/Makefile.am
index df93cef..5b206a0 100644
--- a/src/Makefile.am
+++ b/src/Makefile.am
@@ -45,7 +45,7 @@ libgvnc_1_0_la_CFLAGS = \
 			$(GDK_PIXBUF_CFLAGS) \
 			$(GNUTLS_CFLAGS) \
 			$(SASL_CFLAGS) \
-			$(WARNING_CFLAGS) \
+			$(WARN_CFLAGS) \
 			-DSYSCONFDIR=\""$(sysconfdir)"\" \
 			-DPACKAGE_LOCALE_DIR=\""$(datadir)/locale"\" \
 			-DG_LOG_DOMAIN=\"gvnc\"
@@ -106,7 +106,7 @@ libgvncpulse_1_0_la_LIBADD = \
 libgvncpulse_1_0_la_CFLAGS = \
                        $(GOBJECT_CFLAGS) \
                        $(PULSEAUDIO_CFLAGS) \
-                       $(WARNING_CFLAGS) \
+                       $(WARN_CFLAGS) \
                        -DSYSCONFDIR=\""$(sysconfdir)"\" \
                        -DPACKAGE_LOCALE_DIR=\""$(datadir)/locale"\" \
                        -DG_LOG_DOMAIN=\"pulse-vnc\"
@@ -130,7 +130,7 @@ gtk_vnc_LIBADD = \
 gtk_vnc_CFLAGS = \
 			$(GTK_CFLAGS) \
 			$(X11_CFLAGS) \
-			$(WARNING_CFLAGS) \
+			$(WARN_CFLAGS) \
 			-DSYSCONFDIR=\""$(sysconfdir)"\" \
 			-DPACKAGE_LOCALE_DIR=\""$(datadir)/locale"\" \
 			-DG_LOG_DOMAIN=\"gtk-vnc\"
@@ -293,7 +293,7 @@ pyexec_LTLIBRARIES = gtkvnc.la
 
 gtkvnc_la_LIBADD = libgtk-vnc-$(GTK_VNC_API_VERSION).la $(PYGTK_LIBS)
 gtkvnc_la_CFLAGS = $(GTK_CFLAGS) $(PYTHON_INCLUDES) \
-		   $(PYGTK_CFLAGS) $(WARNING_PYTHON_CFLAGS)
+		   $(PYGTK_CFLAGS) $(WARN_PYTHON_CFLAGS)
 gtkvnc_la_LDFLAGS = -module -avoid-version -fPIC
 gtkvnc_la_SOURCES = vncmodule.c
 nodist_gtkvnc_la_SOURCES = vncmodule.defs.c
[Date Prev][Date Next]   [Thread Prev][Thread Next]   [Thread Index] [Date Index] [Author Index]