[nautilus] Depend on exempi and libexif unless explicitly disabled

[William Jon McCann <mccann src gnome org>]

commit 5bb55d500e5a8b659a3c19b14d425fc1be81bb9b
Author: William Jon McCann <jmccann redhat com>
Date:   Thu Aug 16 13:10:17 2012 -0400

    Depend on exempi and libexif unless explicitly disabled
    
    This allows us to better match our development and test builds
    to what people actually use. And to not silently disable features
    due to missing dependencies at build time.

 configure.in |   50 ++++++++++++++++++++++----------------------------
 1 files changed, 22 insertions(+), 28 deletions(-)
---
diff --git a/configure.in b/configure.in
index f4dc089..9d46f75 100644
--- a/configure.in
+++ b/configure.in
@@ -122,41 +122,35 @@ AC_CHECK_FUNCS(mallopt)
 dnl ==========================================================================
 dnl libexif checking
 
-AM_CONDITIONAL(HAVE_EXIF, false)
 AC_ARG_ENABLE(libexif,
-	AC_HELP_STRING([--disable-libexif],
-			[build without libexif support]))
-msg_libexif=no
-if test "x$enable_libexif" != "xno"; then
-	PKG_CHECK_MODULES(EXIF, libexif >= exif_minver, [
-			  AM_CONDITIONAL(HAVE_EXIF, true)
-			  AC_DEFINE(HAVE_EXIF, 1, [Define to enable EXIF support])
-			  ] msg_libexif=yes,
-			  [AM_CONDITIONAL(HAVE_EXIF, false)])
-
-	AC_SUBST(EXIF_CFLAGS)
-	AC_SUBST(EXIF_LIBS)
+              [AS_HELP_STRING([--enable-exif=@<:@yes/no@:>@],
+                              [build EXIF support [default=yes]])],
+              [enable_exif="$enableval"],
+              [enable_exif=yes])
+
+if test "x$enable_exif" != "xno"; then
+  PKG_CHECK_MODULES(EXIF, libexif >= exif_minver)
+  AC_DEFINE(HAVE_EXIF, 1, [Define to enable EXIF support])
 fi
 
+AM_CONDITIONAL(HAVE_EXIF, test "x$enable_exif" = "xyes")
+
 dnl ==========================================================================
 dnl exempi checking
 
-AM_CONDITIONAL(HAVE_EXEMPI, false)
-AC_ARG_ENABLE(xmp, 
-	AC_HELP_STRING([--disable-xmp], 
-			[build without xmp support]))
-msg_xmp=no
+AC_ARG_ENABLE(xmp,
+              [AS_HELP_STRING([--enable-xmp=@<:@yes/no@:>@],
+                              [build XMP support [default=yes]])],
+              [enable_xmp="$enableval"],
+              [enable_xmp=yes])
+
 if test "x$enable_xmp" != "xno"; then
-	PKG_CHECK_MODULES(EXEMPI, exempi-2.0 >= exempi_minver, [
-		  	  AM_CONDITIONAL(HAVE_EXEMPI, true)
-			  AC_DEFINE(HAVE_EXEMPI, 1, [Define to enable xmp support])
-			  ] msg_xmp=yes,
-	          	  [AM_CONDITIONAL(HAVE_EXEMPI, false)])
-
-	AC_SUBST(EXEMPI_CFLAGS)
-	AC_SUBST(EXEMPI_LIBS)
+  PKG_CHECK_MODULES(EXEMPI, exempi-2.0 >= exempi_minver)
+  AC_DEFINE(HAVE_EXEMPI, 1, [Define to enable XMP support])
 fi
 
+AM_CONDITIONAL(HAVE_EXEMPI, test "x$enable_xmp" = "xyes")
+
 dnl ==========================================================================
 
 dnl ****************************
@@ -348,8 +342,8 @@ nautilus-$VERSION:
 	prefix:                 ${prefix}
 	source code location:	${srcdir}
 	compiler:		${CC}
-	libexif support:	$msg_libexif
-	libexempi support:	$msg_xmp
+	libexif support:	${enable_exif}
+	libexempi support:	${enable_xmp}
 	PackageKit support:     $msg_packagekit
 	nautilus-sendto ext:	$enable_nst_extension
 	Tracker support:	$enable_tracker