[folks] Fix m4 quoting in configure.ac

[Philip Withnall <pwithnall src gnome org>]

commit 13f3aa1e6a7385ec0af534708ab8b5a294c3d262
Author: Philip Withnall <philip withnall collabora co uk>
Date:   Thu Sep 9 18:42:40 2010 +0100

    Fix m4 quoting in configure.ac
    
    (I think.)

 configure.ac |  134 +++++++++++++++++++++++++++++-----------------------------
 1 files changed, 67 insertions(+), 67 deletions(-)
---
diff --git a/configure.ac b/configure.ac
index ae2d4ee..4dcd51c 100644
--- a/configure.ac
+++ b/configure.ac
@@ -1,5 +1,5 @@
 # If not 1, append datestamp to the version number
-m4_define(folks_released, 0)
+m4_define([folks_released], [0])
 
 m4_define([folks_major_version], [0])
 m4_define([folks_minor_version], [1])
@@ -18,23 +18,23 @@ m4_define([folks_lt_age], [13])
 
 # Display the nano_version only if it's not '0'
 m4_define([folks_base_version],
-                [folks_major_version.folks_minor_version.folks_micro_version])
+                folks_major_version.folks_minor_version.folks_micro_version)
 m4_define([folks_full_version],
-                [m4_if(folks_nano_version, 0, [folks_base_version],
-                        [folks_base_version].[folks_nano_version])])
+                [m4_if(folks_nano_version, [0], folks_base_version,
+                        folks_base_version.folks_nano_version)])
 
-m4_define(folks_maybe_datestamp,
+m4_define([folks_maybe_datestamp],
                     m4_esyscmd([if test x]folks_released[ != x1; then date +.%Y%m%d | tr -d '\n\r'; fi]))
 
-m4_define(folks_version, folks_full_version[]folks_maybe_datestamp)
+m4_define([folks_version], folks_full_version[]folks_maybe_datestamp)
 
 # Module API version.
-m4_define([folks_module_version], [folks_lt_current])
+m4_define([folks_module_version], folks_lt_current)
 
-AC_INIT([folks],[folks_version],[https://bugzilla.gnome.org/browse.cgi?product=folks],[folks],[http://telepathy.freedesktop.org/wiki/Folks])
+AC_INIT([folks], folks_version, [https://bugzilla.gnome.org/browse.cgi?product=folks], [folks], [http://telepathy.freedesktop.org/wiki/Folks])
 m4_ifdef([AM_SILENT_RULES], [AM_SILENT_RULES([yes])])
 
-AC_PREREQ(2.65)
+AC_PREREQ([2.65])
 AC_COPYRIGHT([
   Copyright (C) 2010 Collabora Ltd.
 ])
@@ -43,7 +43,7 @@ AC_CONFIG_MACRO_DIR([m4])
 AC_CONFIG_SRCDIR([Makefile.am])
 AC_CONFIG_HEADERS(config.h)
 AC_CONFIG_SRCDIR([configure.ac])
-AM_INIT_AUTOMAKE(1.11 dist-bzip2 no-define no-dist-gzip tar-ustar -Wno-portability)
+AM_INIT_AUTOMAKE([1.11 dist-bzip2 no-define no-dist-gzip tar-ustar -Wno-portability])
 AM_MAINTAINER_MODE
 
 AC_PROG_CC
@@ -51,9 +51,9 @@ AM_PROG_CC_C_O
 AC_DISABLE_STATIC
 LT_INIT
 
-AC_SUBST(CFLAGS)
-AC_SUBST(CPPFLAGS)
-AC_SUBST(LDFLAGS)
+AC_SUBST([CFLAGS])
+AC_SUBST([CPPFLAGS])
+AC_SUBST([LDFLAGS])
 
 # -----------------------------------------------------------
 # Dependencies
@@ -76,28 +76,28 @@ AC_SUBST([LT_CURRENT])
 AC_SUBST([LT_REVISION])
 AC_SUBST([LT_AGE])
 
-PKG_CHECK_MODULES(GLIB,
-                  glib-2.0 >= $GLIB_REQUIRED
-                  gobject-2.0 >= $GLIB_REQUIRED)
-AC_SUBST(GLIB_CFLAGS)
-AC_SUBST(GLIB_LIBS)
+PKG_CHECK_MODULES([GLIB],
+                  [glib-2.0 >= $GLIB_REQUIRED
+                  gobject-2.0 >= $GLIB_REQUIRED])
+AC_SUBST([GLIB_CFLAGS])
+AC_SUBST([GLIB_LIBS])
 
-PKG_CHECK_MODULES(GIO, gio-2.0 >= $GLIB_REQUIRED)
-AC_SUBST(GIO_CFLAGS)
-AC_SUBST(GIO_LIBS)
+PKG_CHECK_MODULES([GIO], [gio-2.0 >= $GLIB_REQUIRED])
+AC_SUBST([GIO_CFLAGS])
+AC_SUBST([GIO_LIBS])
 
-PKG_CHECK_MODULES(DBUS_GLIB, dbus-glib-1)
-AC_SUBST(DBUS_GLIB_CFLAGS)
-AC_SUBST(DBUS_GLIB_LIBS)
+PKG_CHECK_MODULES([DBUS_GLIB], [dbus-glib-1])
+AC_SUBST([DBUS_GLIB_CFLAGS])
+AC_SUBST([DBUS_GLIB_LIBS])
 
 # require GLib >= 2.24 so GLib.Array, etc. reffing is handled automatically
 VALACFLAGS="$VALACFLAGS --target-glib=2.24"
-AC_SUBST(VALACFLAGS)
-AC_SUBST(VALAFLAGS)
-AC_SUBST(VAPIDIR)
+AC_SUBST([VALACFLAGS])
+AC_SUBST([VALAFLAGS])
+AC_SUBST([VAPIDIR])
 
-AC_PATH_PROG(VAPIGEN, vapigen, vapigen)
-AC_SUBST(VAPIGEN)
+AC_PATH_PROG([VAPIGEN], [vapigen], [vapigen])
+AC_SUBST([VAPIGEN])
 
 GOBJECT_INTROSPECTION_REQUIRE([0.6.7])
 
@@ -105,13 +105,13 @@ AS_IF([test "$VAPIGEN" = ""],
 	[AC_MSG_ERROR([Vala must be built with --enable-vapigen])])
 
 # FIXME: We depend on libgee < 0.7 because 0.7 breaks API. bgo#627746
-PKG_CHECK_MODULES(GEE, gee-1.0 < 0.7)
-AC_SUBST(GEE_CFLAGS)
-AC_SUBST(GEE_LIBS)
+PKG_CHECK_MODULES([GEE], [gee-1.0 < 0.7])
+AC_SUBST([GEE_CFLAGS])
+AC_SUBST([GEE_LIBS])
 
-PKG_CHECK_MODULES(TP_GLIB, telepathy-glib >= $TP_GLIB_REQUIRED)
-AC_SUBST(TP_GLIB_CFLAGS)
-AC_SUBST(TP_GLIB_LIBS)
+PKG_CHECK_MODULES([TP_GLIB], [telepathy-glib >= $TP_GLIB_REQUIRED])
+AC_SUBST([TP_GLIB_CFLAGS])
+AC_SUBST([TP_GLIB_LIBS])
 
 VALA_CHECK_PACKAGES([telepathy-glib
                     dbus-glib-1
@@ -126,19 +126,19 @@ AC_CHECK_FUNCS([strstr])
 # Backends
 # -----------------------------------------------------------
 
-FOLKS_MODULE_VERSION=folks_module_version()
-AC_SUBST(FOLKS_MODULE_VERSION)
-AC_DEFINE([MODULE_VERSION], ["folks_module_version()"],
+FOLKS_MODULE_VERSION=folks_module_version
+AC_SUBST([FOLKS_MODULE_VERSION])
+AC_DEFINE([MODULE_VERSION], "folks_module_version",
           [Module interface version])
 
 BACKEND_DIR='$(libdir)/folks/$(FOLKS_MODULE_VERSION)/backends'
-AC_SUBST(BACKEND_DIR)
+AC_SUBST([BACKEND_DIR])
 
 # -----------------------------------------------------------
 # Tests
 # -----------------------------------------------------------
-PKG_CHECK_MODULES(TP_GLIB_FOR_TESTS,
-                  telepathy-glib >= $TP_GLIB_TESTS_REQUIRED,
+PKG_CHECK_MODULES([TP_GLIB_FOR_TESTS],
+                  [telepathy-glib >= $TP_GLIB_TESTS_REQUIRED],
                   [have_tp_glib_for_tests=true],
                   [have_tp_glib_for_tests=false])
 AM_CONDITIONAL([HAVE_TP_GLIB_FOR_TESTS], [$have_tp_glib_for_tests])
@@ -146,40 +146,40 @@ AM_CONDITIONAL([HAVE_TP_GLIB_FOR_TESTS], [$have_tp_glib_for_tests])
 # -----------------------------------------------------------
 # Documentation
 # -----------------------------------------------------------
-AC_ARG_ENABLE(docs,
+AC_ARG_ENABLE([docs],
   AS_HELP_STRING([--enable-docs],[Enable documentation generation]),
-    enable_docs=$enableval, enable_docs=no)
-AM_CONDITIONAL(ENABLE_DOCS, test x$enable_docs = xyes)
+    [enable_docs=$enableval], [enable_docs=no])
+AM_CONDITIONAL([ENABLE_DOCS], [test x$enable_docs = xyes])
 
 AS_IF([test "x$enable_docs" != xno],
-  [AC_PATH_PROG(VALADOC, valadoc, :)
-   AC_SUBST(VALADOC)
+  [AC_PATH_PROG([VALADOC], [valadoc], [:])
+   AC_SUBST([VALADOC])
    AS_IF([test "$VALADOC" = :],
      [AC_MSG_ERROR([valadoc not found])])])
 
 # -----------------------------------------------------------
 # Error flags
 # -----------------------------------------------------------
-AS_COMPILER_FLAG(-Wall, ERROR_CFLAGS="-Wall", ERROR_CFLAGS="")
-AS_COMPILER_FLAG(-Werror, werror=yes, werror=no)
+AS_COMPILER_FLAG([-Wall], [ERROR_CFLAGS="-Wall"], [ERROR_CFLAGS=""])
+AS_COMPILER_FLAG([-Werror], [werror=yes], [werror=no])
 
-AC_ARG_ENABLE(debug,
+AC_ARG_ENABLE([debug],
   AS_HELP_STRING([--disable-debug],[compile without debug code]),
-    enable_debug=$enableval, enable_debug=yes)
+    [enable_debug=$enableval], [enable_debug=yes])
 
-AC_ARG_ENABLE(Werror,
+AC_ARG_ENABLE([Werror],
   AS_HELP_STRING([--disable-Werror],[compile without -Werror (normally enabled in development builds)]),
-    werror=$enableval, werror=yes)
+    [werror=$enableval], [werror=yes])
 
-AS_COMPILER_FLAG(-Wextra, wextra=yes, wextra=no)
-AS_COMPILER_FLAG(-Wno-missing-field-initializers,
-        wno_missing_field_initializers=yes,
-        wno_missing_field_initializers=no)
-AS_COMPILER_FLAG(-Wno-unused-parameter,
-        wno_unused_parameter=yes,
-        wno_unused_parameter=no)
+AS_COMPILER_FLAG([-Wextra], [wextra=yes], [wextra=no])
+AS_COMPILER_FLAG([-Wno-missing-field-initializers],
+        [wno_missing_field_initializers=yes],
+        [wno_missing_field_initializers=no])
+AS_COMPILER_FLAG([-Wno-unused-parameter],
+        [wno_unused_parameter=yes],
+        [wno_unused_parameter=no])
 
-ifelse(folks_released, 1, [],
+ifelse(folks_released, [1], [],
     [
         if test x$werror = xyes; then
             ERROR_CFLAGS="$ERROR_CFLAGS -Werror"
@@ -191,14 +191,14 @@ ifelse(folks_released, 1, [],
         fi
     ])
 
-AS_COMPILER_FLAG(-D_POSIX_SOURCE, ERROR_CFLAGS="$ERROR_CFLAGS -D_POSIX_SOURCE")
-AS_COMPILER_FLAG(-std=c99, ERROR_CFLAGS="$ERROR_CFLAGS -std=c99")
-AS_COMPILER_FLAG(-Wshadow, ERROR_CFLAGS="$ERROR_CFLAGS -Wshadow")
-AS_COMPILER_FLAG(-Wmissing-prototypes, ERROR_CFLAGS="$ERROR_CFLAGS -Wmissing-prototypes")
-AS_COMPILER_FLAG(-Wmissing-declarations, ERROR_CFLAGS="$ERROR_CFLAGS -Wmissing-declarations")
-AS_COMPILER_FLAG(-Wstrict-prototypes, ERROR_CFLAGS="$ERROR_CFLAGS -Wstrict-prototypes")
+AS_COMPILER_FLAG([-D_POSIX_SOURCE], [ERROR_CFLAGS="$ERROR_CFLAGS -D_POSIX_SOURCE"])
+AS_COMPILER_FLAG([-std=c99], [ERROR_CFLAGS="$ERROR_CFLAGS -std=c99"])
+AS_COMPILER_FLAG([-Wshadow], [ERROR_CFLAGS="$ERROR_CFLAGS -Wshadow"])
+AS_COMPILER_FLAG([-Wmissing-prototypes], [ERROR_CFLAGS="$ERROR_CFLAGS -Wmissing-prototypes"])
+AS_COMPILER_FLAG([-Wmissing-declarations], [ERROR_CFLAGS="$ERROR_CFLAGS -Wmissing-declarations"])
+AS_COMPILER_FLAG([-Wstrict-prototypes], [ERROR_CFLAGS="$ERROR_CFLAGS -Wstrict-prototypes"])
 
-AC_SUBST(ERROR_CFLAGS)
+AC_SUBST([ERROR_CFLAGS])
 
 # -----------------------------------------------------------
 # Final output