[vala] D-Bus: Add test for sending and receiving errors

[Jürg Billeter <juergbi src gnome org>]

commit e4138336cb4700df9715822ea96789847df2c8a7
Author: Jürg Billeter <j bitron ch>
Date:   Tue Oct 19 10:57:05 2010 +0200

    D-Bus: Add test for sending and receiving errors

 tests/Makefile.am            |    2 +
 tests/dbus/async-errors.test |   96 ++++++++++++++++++++++++++++++++++++++++++
 tests/dbus/errors.test       |   81 +++++++++++++++++++++++++++++++++++
 3 files changed, 179 insertions(+), 0 deletions(-)
---
diff --git a/tests/Makefile.am b/tests/Makefile.am
index 66b8c8f..26436cc 100644
--- a/tests/Makefile.am
+++ b/tests/Makefile.am
@@ -92,7 +92,9 @@ TESTS = \
 	dbus/basic-types.test \
 	dbus/arrays.test \
 	dbus/structs.test \
+	dbus/errors.test \
 	dbus/async.test \
+	dbus/async-errors.test \
 	dbus/signals.test \
 	dbus/bug596862.vala \
 	dbus/bug602003.test \
diff --git a/tests/dbus/async-errors.test b/tests/dbus/async-errors.test
new file mode 100644
index 0000000..7dd3edb
--- /dev/null
+++ b/tests/dbus/async-errors.test
@@ -0,0 +1,96 @@
+Packages: gio-2.0
+D-Bus
+
+Program: client
+
+[DBus (name = "org.example.Test")]
+interface Test : Object {
+	public abstract async void test_void () throws Error;
+	public abstract async int test_int (int i, out int j) throws Error;
+	public abstract async string test_string (string s, out string t) throws Error;
+}
+
+MainLoop main_loop;
+
+async void run (Test test) {
+	try {
+		yield test.test_void ();
+		assert_not_reached ();
+	} catch {
+	}
+
+	try {
+		int j, k;
+		k = yield test.test_int (42, out j);
+		assert_not_reached ();
+	} catch {
+	}
+
+	try {
+		string t, u;
+		u = yield test.test_string ("hello", out t);
+		assert_not_reached ();
+	} catch {
+	}
+
+	main_loop.quit ();
+}
+
+void main () {
+	// client
+	Test test = Bus.get_proxy_sync (BusType.SESSION, "org.example.Test", "/org/example/test");
+
+	run.begin (test);
+
+	main_loop = new MainLoop (null, false);
+	main_loop.run ();
+}
+
+Program: server
+
+[DBus (name = "org.example.Test")]
+class Test : Object {
+	public async void test_void () throws Error {
+		Idle.add (test_void.callback);
+		yield;
+		throw new IOError.FAILED ("Operation failed");
+	}
+
+	public async int test_int (int i, out int j) throws Error {
+		Idle.add (test_int.callback);
+		yield;
+		throw new IOError.FAILED ("Operation failed");
+	}
+
+	public async string test_string (string s, out string t) throws Error {
+		Idle.add (test_string.callback);
+		yield;
+		throw new IOError.FAILED ("Operation failed");
+	}
+}
+
+MainLoop main_loop;
+
+void client_exit (Pid pid, int status) {
+	// client finished, terminate server
+	assert (status == 0);
+	main_loop.quit ();
+}
+
+void main () {
+	var conn = Bus.get_sync (BusType.SESSION);
+	conn.register_object ("/org/example/test", new Test ());
+
+	// try to register service in session bus
+	var request_result = conn.call_sync ("org.freedesktop.DBus", "/org/freedesktop/DBus", "org.freedesktop.DBus", "RequestName",
+	                                      new Variant ("(su)", "org.example.Test", 0x4), null, 0, -1);
+	assert ((uint) request_result.get_child_value (0) == 1);
+
+	// server ready, spawn client
+	Pid client_pid;
+	Process.spawn_async (null, { "test", "/dbus/async-errors/client" }, null, SpawnFlags.DO_NOT_REAP_CHILD, null, out client_pid);
+	ChildWatch.add (client_pid, client_exit);
+
+	main_loop = new MainLoop ();
+	main_loop.run ();
+}
diff --git a/tests/dbus/errors.test b/tests/dbus/errors.test
new file mode 100644
index 0000000..826aeb3
--- /dev/null
+++ b/tests/dbus/errors.test
@@ -0,0 +1,81 @@
+Packages: gio-2.0
+D-Bus
+
+Program: client
+
+[DBus (name = "org.example.Test")]
+interface Test : Object {
+	public abstract void test_void () throws Error;
+	public abstract int test_int (int i, out int j) throws Error;
+	public abstract string test_string (string s, out string t) throws Error;
+}
+
+void main () {
+	// client
+	Test test = Bus.get_proxy_sync (BusType.SESSION, "org.example.Test", "/org/example/test");
+
+	try {
+		test.test_void ();
+		assert_not_reached ();
+	} catch {
+	}
+
+	try {
+		int j, k;
+		k = test.test_int (42, out j);
+		assert_not_reached ();
+	} catch {
+	}
+
+	try {
+		string t, u;
+		u = test.test_string ("hello", out t);
+		assert (t == "world");
+		assert (u == "vala");
+		assert_not_reached ();
+	} catch {
+	}
+}
+
+Program: server
+
+[DBus (name = "org.example.Test")]
+class Test : Object {
+	public void test_void () throws Error {
+		throw new IOError.FAILED ("Operation failed");
+	}
+
+	public int test_int (int i, out int j) throws Error {
+		throw new IOError.FAILED ("Operation failed");
+	}
+
+	public string test_string (string s, out string t) throws Error {
+		throw new IOError.FAILED ("Operation failed");
+	}
+}
+
+MainLoop main_loop;
+
+void client_exit (Pid pid, int status) {
+	// client finished, terminate server
+	assert (status == 0);
+	main_loop.quit ();
+}
+
+void main () {
+	var conn = Bus.get_sync (BusType.SESSION);
+	conn.register_object ("/org/example/test", new Test ());
+
+	// try to register service in session bus
+	var request_result = conn.call_sync ("org.freedesktop.DBus", "/org/freedesktop/DBus", "org.freedesktop.DBus", "RequestName",
+	                                      new Variant ("(su)", "org.example.Test", 0x4), null, 0, -1);
+	assert ((uint) request_result.get_child_value (0) == 1);
+
+	// server ready, spawn client
+	Pid client_pid;
+	Process.spawn_async (null, { "test", "/dbus/errors/client" }, null, SpawnFlags.DO_NOT_REAP_CHILD, null, out client_pid);
+	ChildWatch.add (client_pid, client_exit);
+
+	main_loop = new MainLoop ();
+	main_loop.run ();
+}