[glibmm] Begin transition to new build infrastructure



commit 7a5a8e6efc4485a55f998488ca9e6fa52ff98397
Author: Daniel Elstner <danielk openismus com>
Date:   Fri Aug 7 19:30:47 2009 +0200

    Begin transition to new build infrastructure
    
    * autogen.sh: Replace script with a minimalistic wrapper around
    mm-common-prepare, autoreconf and configure.
    * Makefile.am (ACLOCAL_AMFLAGS): Pick up ${ACLOCAL_FLAGS} from the
    environment, so that autoreconf can do its magic.
    * configure.ac: Modernize.  Cut loads of old cruft.  Make use of
    magic mm-common macros to simplify things.  Declare build/ as the
    destination for auxiliary build files.  Add TODO comments to flag
    the pieces that still need cutting.  Re-enable autoheader.
    * config.h.in: Remove file, and have autoheader generate it.

 ChangeLog        |   14 +++
 Makefile.am      |    2 +-
 autogen.sh       |   84 +--------------
 build/.gitignore |   10 ++
 config.h.in      |    6 -
 configure.ac     |  307 +++++++++++++++---------------------------------------
 6 files changed, 114 insertions(+), 309 deletions(-)
---
diff --git a/ChangeLog b/ChangeLog
index 4e15ec5..eb784b2 100644
--- a/ChangeLog
+++ b/ChangeLog
@@ -1,3 +1,17 @@
+2009-08-07  Daniel Elstner  <danielk openismus com>
+
+	Begin transition to new build infrastructure
+
+	* autogen.sh: Replace script with a minimalistic wrapper around
+	mm-common-prepare, autoreconf and configure.
+	* Makefile.am (ACLOCAL_AMFLAGS): Pick up ${ACLOCAL_FLAGS} from the
+	environment, so that autoreconf can do its magic.
+	* configure.ac: Modernize.  Cut loads of old cruft.  Make use of
+	magic mm-common macros to simplify things.  Declare build/ as the
+	destination for auxiliary build files.  Add TODO comments to flag
+	the pieces that still need cutting.  Re-enable autoheader.
+	* config.h.in: Remove file, and have autoheader generate it.
+
 2009-07-27  José Alburquerque  <jaalburqu svn gnome org>
 
 	* gio/src/memoryinputstream.ccg: Correct the if condition in
diff --git a/Makefile.am b/Makefile.am
index 3de355f..f2ebb78 100644
--- a/Makefile.am
+++ b/Makefile.am
@@ -1,4 +1,4 @@
-ACLOCAL_AMFLAGS	= -I scripts
+ACLOCAL_AMFLAGS	= -I scripts ${ACLOCAL_FLAGS}
 
 SUBDIRS		= tools glib gio examples scripts tests MSVC_Net2005 MSVC_Net2008 docs
 DIST_SUBDIRS	= $(SUBDIRS)
diff --git a/autogen.sh b/autogen.sh
index 26f3a81..fed2c5b 100755
--- a/autogen.sh
+++ b/autogen.sh
@@ -1,79 +1,7 @@
-#! /bin/sh
-
-PKG_NAME=glibmm
-
-srcdir=`dirname $0`
-test "x$srcdir" = x && srcdir=.
-
-origdir=`pwd`
-
-if test -f "$srcdir/configure.ac" && \
-   test -d "$srcdir/glib/src" && \
-   test -d "$srcdir/glib/glibmm"
-then :; else
-    echo "** Error **: Directory \`${srcdir}\' does not look like"
-    echo "the top-level ${PKG_NAME} directory."
-    exit 1
-fi
-
-MAKE=`which gnumake`
-test -x "$MAKE" || MAKE=`which gmake`
-test -x "$MAKE" || MAKE=`which make`
-
-if "$MAKE" --version 2>/dev/null | grep "Free Software Foundation" >/dev/null 2>&1
-then :; else
-    echo "** Error **: You need GNU make to build gtkmm from CVS."
-    echo "${MAKE} is not GNU make."
-    exit 1
-fi
-
-echo "Found GNU make at ${MAKE}... good."
-
-cd "$srcdir"
-
-echo "Adding libtools."
-libtoolize --automake || exit 1
-
-echo "Building macros."
-aclocal -I "$srcdir/scripts" $ACLOCAL_FLAGS || exit 1
-
-#echo "Building config header."
-#autoheader
-
-echo "Building makefiles."
-automake --add-missing || exit 1
-
-echo "Building configure."
-
-autoconf || exit 1
-
-
-enable_warnings=
-
-case "$*" in
-    *--enable-warnings*|*--disable-warnings*)
-        ;;
-    *)  # enable -Werror by default when building with gcc3
-        ${CXX:-"g++"} --version 2>/dev/null | grep '(GCC) 3\.[0-9]\+\.[0-9]' >/dev/null 2>&1 \
-            && enable_warnings='--enable-warnings=hardcore'
-        ;;
-esac
-
-cd "$origdir"
-rm -f config.cache
-
-if test -z "$AUTOGEN_SUBDIR_MODE"
-then
-    echo "Running $srcdir/configure --enable-maintainer-mode" $enable_warnings "$@"
-    "$srcdir/configure" --enable-maintainer-mode $enable_warnings "$@" || exit 1
-    echo
-    echo 'run "make"'
-    echo
-else
-    echo
-    echo 'run "./configure ; make"'
-    echo
-fi
-
-exit 0
+#! /bin/sh -e
+test -n "$srcdir" || srcdir=`dirname "$0"`
+test -n "$srcdir" || srcdir=.
 
+mm-common-prepare --force --copy "$srcdir"
+autoreconf --force --install "$srcdir"
+test -n "$NOCONFIGURE" || "$srcdir/configure" --enable-maintainer-mode "$@"
diff --git a/build/.gitignore b/build/.gitignore
new file mode 100644
index 0000000..1d15581
--- /dev/null
+++ b/build/.gitignore
@@ -0,0 +1,10 @@
+/compile-binding.am
+/config.guess
+/config.sub
+/depcomp
+/dist-changelog.am
+/doc-reference.am
+/generate-binding.am
+/install-sh
+/ltmain.sh
+/missing
diff --git a/configure.ac b/configure.ac
index 5b5fc9d..27176e5 100644
--- a/configure.ac
+++ b/configure.ac
@@ -12,212 +12,87 @@
 #  Copyright 1998 Stephan Kulow 
 #
 
-pushdef([GLIBMM_MAJOR_VERSION],     [2])
-pushdef([GLIBMM_MINOR_VERSION],     [21])
-pushdef([GLIBMM_MICRO_VERSION],     [3])
-pushdef([GLIBMM_EXTRA_VERSION],     [])
-pushdef([GLIBMM_VERSION], GLIBMM_MAJOR_VERSION.GLIBMM_MINOR_VERSION.GLIBMM_MICRO_VERSION[]GLIBMM_EXTRA_VERSION)
-
-AC_INIT([glibmm], GLIBMM_VERSION, [gtkmm-list gnome org])
-AC_PREREQ([2.58])
-AC_CONFIG_SRCDIR([glib/glibmmconfig.h.in])
-AC_CONFIG_MACRO_DIR([scripts])
+AC_INIT([glibmm], [2.21.3], [http://bugzilla.gnome.org/enter_bug.cgi?product=glibmm],
+        [glibmm], [http://www.gtkmm.org/])
+AC_PREREQ([2.59])
+m4_pattern_forbid([^_?MM_])
 
-#########################################################################
-#  Version and initialization
-#########################################################################
-[GLIBMM_MAJOR_VERSION]=GLIBMM_MAJOR_VERSION
-[GLIBMM_MINOR_VERSION]=GLIBMM_MINOR_VERSION
-[GLIBMM_MICRO_VERSION]=GLIBMM_MICRO_VERSION
-[GLIBMM_EXTRA_VERSION]=GLIBMM_EXTRA_VERSION
-[GLIBMM_VERSION]=GLIBMM_VERSION
-popdef([GLIBMM_MAJOR_VERSION])
-popdef([GLIBMM_MINOR_VERSION])
-popdef([GLIBMM_MICRO_VERSION])
-popdef([GLIBMM_EXTRA_VERSION])
-popdef([GLIBMM_VERSION])
-GLIBMM_RELEASE=$GLIBMM_MAJOR_VERSION.$GLIBMM_MINOR_VERSION
-AC_DEFINE_UNQUOTED(GLIBMM_MAJOR_VERSION, $GLIBMM_MAJOR_VERSION, [Major version of gtkmm])
-AC_DEFINE_UNQUOTED(GLIBMM_MINOR_VERSION, $GLIBMM_MINOR_VERSION, [Minor version of gtkmm])
-AC_DEFINE_UNQUOTED(GLIBMM_MICRO_VERSION, $GLIBMM_MICRO_VERSION, [Micro version of gtkmm])
-AC_SUBST(GLIBMM_MAJOR_VERSION)
-AC_SUBST(GLIBMM_MINOR_VERSION)
-AC_SUBST(GLIBMM_MICRO_VERSION)
-AC_SUBST(GLIBMM_VERSION)
-AC_SUBST(GLIBMM_RELEASE)
+AC_CONFIG_SRCDIR([glib/glibmm.h])
+AC_CONFIG_AUX_DIR([build])
+AC_CONFIG_MACRO_DIR([scripts])
+AC_CONFIG_HEADERS([config.h glib/glibmmconfig.h gio/giommconfig.h])
 
-#
-# +1 : ? : +1  == new interface that does not break old one
-# +1 : ? : 0   == new interface that breaks old one
-#  ? : ? : 0   == no new interfaces, but breaks apps
-#  ? :+1 : ?   == just some internal changes, nothing breaks but might work 
-#                 better
-# CURRENT : REVISION : AGE
-LIBGLIBMM_SO_VERSION=3:0:2
-AC_SUBST(LIBGLIBMM_SO_VERSION)
-
-AC_CONFIG_AUX_DIR(scripts)
-
-dnl Initialize automake stuff
-AM_INIT_AUTOMAKE([1.7 gnu])
-
-dnl Specify a configuration file (no autoheader)
-AM_CONFIG_HEADER(config.h glib/glibmmconfig.h gio/giommconfig.h)
+AM_INIT_AUTOMAKE([1.9 -Wno-portability dist-bzip2 no-define nostdinc tar-ustar])
 AM_MAINTAINER_MODE
-AL_ACLOCAL_INCLUDE(scripts)
-
-
-#########################################################################
-#  Configure arguments 
-#########################################################################
-
-#########################################################################
-#  Environment Checks
-#########################################################################
-AC_PROG_CC
-AC_PROG_CPP
-AC_PROG_MAKE_SET
-AC_CANONICAL_BUILD
-AC_CANONICAL_HOST
-
-dnl Used for enabling the "-no-undefined" flag while generating DLLs
-dnl Copied from the official gtk+-2 configure.in
-AC_MSG_CHECKING([for some Win32 platform])
-case "$host" in
-  *-*-mingw*|*-*-cygwin*)
-    platform_win32=yes
-    ;;
-  *)
-    platform_win32=no
-    ;;
-esac
-AC_MSG_RESULT([$platform_win32])
-AM_CONDITIONAL(PLATFORM_WIN32, test "$platform_win32" = "yes")
-
-AC_MSG_CHECKING([for native Win32])
-case "$host" in
-  *-*-mingw*)
-    os_win32=yes
-    ;;
-  *)
-    os_win32=no
-    ;;
-esac
-AC_MSG_RESULT([$os_win32])
-AM_CONDITIONAL(OS_WIN32, test "$os_win32" = "yes")
-
-# Disable static libraries by default
-AC_DISABLE_STATIC
+AC_ARG_VAR([ACLOCAL_FLAGS], [aclocal flags, e.g. -I <macro dir>])
+
+MM_INIT_MODULE([glibmm-2.4], m4_expand([AC_PACKAGE_VERSION]))
+MM_INIT_MODULE([giomm-2.4],  m4_expand([AC_PACKAGE_VERSION]))
 
-if test x$enable_static = "xyes"; then
-	AC_DEFINE([GLIBMM_STATIC_LIB],[1], [Defined when glibmm is built as a static library])
-	AC_DEFINE([GIOMM_STATIC_LIB],[1], [Defined when giomm is built as a static library])
-fi
+# http://www.gnu.org/software/libtool/manual/html_node/Updating-version-info.html
+AC_SUBST([LIBGLIBMM_SO_VERSION], [3:0:2])
 
+AC_PROG_CXX
+AC_DISABLE_STATIC
 AC_LIBTOOL_WIN32_DLL
 AC_PROG_LIBTOOL
 
-AL_PROG_GNU_M4(AC_MSG_ERROR([dnl
-SUN m4 does not work for building gtkmm. 
-Please install GNU m4.]))
-
-AL_PROG_GNU_MAKE(AC_MSG_ERROR([dnl
-SUN make does not work for building gtkmm.
-Please install GNU make.]))
+AC_MSG_CHECKING([for Windows operating system])
+AS_CASE([$host_os], [cygwin*|mingw*], [glibmm_platform_win32=yes], [glibmm_platform_win32=no])
+AC_MSG_RESULT([$glibmm_platform_win32])
+AM_CONDITIONAL([PLATFORM_WIN32], [test "x$glibmm_platform_win32" = xyes])
 
-GLIBMM_CHECK_PERL([5.6.0])
+AC_MSG_CHECKING([for native Win32 host environment])
+AS_CASE([$host_os], [mingw*], [glibmm_os_win32=yes], [glibmm_os_win32=no])
+AC_MSG_RESULT([$glibmm_os_win32])
+AM_CONDITIONAL([OS_WIN32], [test "x$glibmm_os_win32" = xyes])
 
-#########################################################################
-#  Function checks
-#########################################################################
+AS_IF([test "x$enable_static" = xyes],
+[
+  AC_DEFINE([GLIBMM_STATIC_LIB], [1], [Defined when glibmm is built as a static library])
+  AC_DEFINE([GIOMM_STATIC_LIB],  [1], [Defined when giomm is built as a static library])
+])
 
-# functions used in demos/gtk-demo. Undefined in config.h !
 AC_CHECK_FUNCS([flockfile funlockfile getc_unlocked mkfifo])
 
-#########################################################################
-#  Dependancy checks
-#########################################################################
-gtkmm_min_sigc_version=2.0.0
-gtkmm_min_glib_version=2.21.1
-
-PKG_CHECK_MODULES(GLIBMM, sigc++-2.0 >= ${gtkmm_min_sigc_version} glib-2.0 >= ${gtkmm_min_glib_version} gobject-2.0 >= ${gtkmm_min_glib_version} gmodule-2.0 >= ${gtkmm_min_glib_version})
-AC_SUBST(GLIBMM_CFLAGS)
-AC_SUBST(GLIBMM_LIBS)
-
-
-# Only check for gio-unix-2.0 on non-win32 platform, because that API is Unix-specific. 
-if test x"$os_win32" = xyes; then
-  PKG_CHECK_MODULES(GIOMM, sigc++-2.0 >= ${gtkmm_min_sigc_version} glib-2.0 >= ${gtkmm_min_glib_version} gobject-2.0 >= ${gtkmm_min_glib_version} gmodule-2.0 >= ${gtkmm_min_glib_version} gio-2.0 >= ${gtkmm_min_glib_version})
-else
-  PKG_CHECK_MODULES(GIOMM, sigc++-2.0 >= ${gtkmm_min_sigc_version} glib-2.0 >= ${gtkmm_min_glib_version} gobject-2.0 >= ${gtkmm_min_glib_version} gmodule-2.0 >= ${gtkmm_min_glib_version} gio-2.0 >= ${gtkmm_min_glib_version} gio-unix-2.0 >= ${gtkmm_min_glib_version})
-fi
-AC_SUBST(GIOMM_CFLAGS)
-AC_SUBST(GIOMM_LIBS)
-
-# gthread isn't a requirement, but we should use its CFLAGS if available.
-PKG_CHECK_MODULES(GTHREAD, gthread-2.0 >= ${gtkmm_min_glib_version},[],[GTHREAD_CFLAGS=''; GTHREAD_LIBS=''])
-AC_SUBST(GTHREAD_CFLAGS)
-AC_SUBST(GTHREAD_LIBS)
-
-#location to install gmmproc tools
-GMMPROC_DIR=[${libdir}/glibmm-2.4/proc]
-AC_SUBST([GMMPROC_DIR])
-
-#########################################################################
-#  C++ checks
-#########################################################################
-AC_PROG_CXX
+GLIBMM_MODULES='sigc++-2.0 >= 2.0 glib-2.0 >= 2.21.1 gobject-2.0 >= 2.21.1 gmodule-2.0 >= 2.21.1'
+PKG_CHECK_MODULES([GLIBMM], [$GLIBMM_MODULES])
+
+GIOMM_MODULES="$GLIBMM_MODULES gio-2.0 >= 2.21.1"
+test "x$glibmm_os_win32" = xyes || GIOMM_MODULES="$GIOMM_MODULES gio-unix-2.0 >= 2.21.1"
+PKG_CHECK_MODULES([GIOMM], [$GIOMM_MODULES])
+
+MM_PKG_CONFIG_SUBST([GTHREAD_CFLAGS], [--cflags-only-other gthread-2.0])
+MM_PKG_CONFIG_SUBST([GTHREAD_LIBS], [--libs gthread-2.0])
+
+# Location to install gmmproc tools
+# TODO: There is no reason for this to be a substitution variable
+AC_SUBST([GMMPROC_DIR], ['${libdir}/glibmm-2.4/proc'])
+
+AC_CHECK_PROGS([M4], [gm4 m4], [m4])
+
+# TODO: Temporary hack
+AC_PATH_PROG([PERL_PATH], [perl], [perl])
 
 # Check for the SUN Forte compiler, and define GLIBMM_COMPILER_SUN_FORTE in the header.
 GLIBMM_PROG_CXX_SUN
 
 # Ensure MSVC-compatible struct packing convention is used when
 # compiling for Win32 with gcc.
-# What flag to depends on gcc version: gcc3 uses "-mms-bitfields", while
-# gcc2 uses "-fnative-struct".
-if test x"$os_win32" = xyes; then
-  if test x"$GCC" = xyes -a x"$GXX" = xyes; then
-    msnative_struct=''
-    AC_MSG_CHECKING([how to get MSVC-compatible struct packing])
-    if test -z "$ac_cv_prog_CC"; then
-      our_gcc="$CC"
-    else
-      our_gcc="$ac_cv_prog_CC"
-    fi
-    case `$our_gcc --version | sed -e 's,\..*,.,' -e q` in
-      2.)
-	if $our_gcc -v --help 2>/dev/null | grep fnative-struct >/dev/null; then
-	  msnative_struct='-fnative-struct'
-	fi
-	;;
-      *)
-	if $our_gcc -v --help 2>/dev/null | grep ms-bitfields >/dev/null; then
-	  msnative_struct='-mms-bitfields'
-	fi
-	;;
-    esac
-    if test x"$msnative_struct" = x ; then
-      AC_MSG_RESULT([no way])
-      AC_MSG_WARN([produced libraries might be incompatible with MSVC-compiled code])
-    else
-      CXXFLAGS="$CXXFLAGS $msnative_struct"
-      AC_MSG_RESULT([${msnative_struct}])
-    fi
-  fi
-fi
+# TODO: Disabled for now. I don't think this should be enabled by the
+# libraries themselves on behalf of the user.  That makes no sense as
+# it is a platform-wide ABI choice.
 
 AC_LANG([C++])
 
-AC_CXX_BOOL(,config_error=yes)
-AC_CXX_NAMESPACES(,config_error=yes)
-AC_CXX_MUTABLE(,config_error=yes)
+# TODO: I think we can just get rid of these checks.
+glibmm_config_error=no
+AC_CXX_BOOL(,       [glibmm_config_error=yes])
+AC_CXX_NAMESPACES(, [glibmm_config_error=yes])
+AC_CXX_MUTABLE(,    [glibmm_config_error=yes])
 
-AC_MSG_CHECKING(if C++ environment provides all required features)
-if test "x$config_error" = xyes ; then
-  AC_MSG_RESULT([no])
-  AC_MSG_ERROR([Your compiler is not powerful enough to compile gtkmm. If it should be, see config.log for more information of why it failed.])
-fi
-AC_MSG_RESULT([yes])
+AS_IF([test "x$glibmm_config_error" = xyes],
+      [AC_MSG_FAILURE([[Your compiler is not powerful enough to compile glibmm.]])])
 
 AC_CHECK_SIZEOF([wchar_t])
 DK_CHECK_FEATURE([wide stream],
@@ -226,64 +101,50 @@ DK_CHECK_FEATURE([wide stream],
                   [[std::wostringstream s; (void) s.str();]])
 ])
 
-GLIBMM_CXX_HAS_NAMESPACE_STD()
-GLIBMM_CXX_HAS_STD_ITERATOR_TRAITS()
-GLIBMM_CXX_HAS_SUN_REVERSE_ITERATOR()
-GLIBMM_CXX_HAS_TEMPLATE_SEQUENCE_CTORS()
-GLIBMM_CXX_MEMBER_FUNCTIONS_MEMBER_TEMPLATES()
-GLIBMM_CXX_CAN_DISAMBIGUATE_CONST_TEMPLATE_SPECIALIZATIONS()
-GLIBMM_CXX_CAN_USE_DYNAMIC_CAST_IN_UNUSED_TEMPLATE_WITHOUT_DEFINITION()
-GLIBMM_CXX_CAN_ASSIGN_NON_EXTERN_C_FUNCTIONS_TO_EXTERN_C_CALLBACKS()
-GLIBMM_CXX_CAN_USE_NAMESPACES_INSIDE_EXTERNC()
-GLIBMM_CXX_ALLOWS_STATIC_INLINE_NPOS()
-GLIBMM_C_STD_TIME_T_IS_NOT_INT32()
-
+GLIBMM_CXX_HAS_NAMESPACE_STD
+GLIBMM_CXX_HAS_STD_ITERATOR_TRAITS
+GLIBMM_CXX_HAS_SUN_REVERSE_ITERATOR
+GLIBMM_CXX_HAS_TEMPLATE_SEQUENCE_CTORS
+GLIBMM_CXX_MEMBER_FUNCTIONS_MEMBER_TEMPLATES
+GLIBMM_CXX_CAN_DISAMBIGUATE_CONST_TEMPLATE_SPECIALIZATIONS
+GLIBMM_CXX_CAN_USE_DYNAMIC_CAST_IN_UNUSED_TEMPLATE_WITHOUT_DEFINITION
+GLIBMM_CXX_CAN_ASSIGN_NON_EXTERN_C_FUNCTIONS_TO_EXTERN_C_CALLBACKS
+GLIBMM_CXX_CAN_USE_NAMESPACES_INSIDE_EXTERNC
+GLIBMM_CXX_ALLOWS_STATIC_INLINE_NPOS
+GLIBMM_C_STD_TIME_T_IS_NOT_INT32
 
 # Create a list of input directories for Doxygen.
+# TODO: kill
 GTKMM_DOXYGEN_INPUT_SUBDIRS([glib gio])
 
 # Check whether --enable-debug-refcounting was given.
-GLIBMM_ARG_ENABLE_DEBUG_REFCOUNTING()
+GLIBMM_ARG_ENABLE_DEBUG_REFCOUNTING
 
 # Evaluate the --enable-warnings=level option.
-DK_ARG_ENABLE_WARNINGS([GLIBMM_WXXFLAGS],
+MM_ARG_ENABLE_WARNINGS([GLIBMM_WXXFLAGS],
                        [-Wall],
-                       [-pedantic -Wall -Wextra])
-
-# Add an --enable-use-deprecations configure option:
-AC_ARG_ENABLE(deprecations,
-              [AC_HELP_STRING([--enable-use-deprecations],
-                              [warn about deprecated usages [default=no]])],,
-              [enable_deprecations=no])
+                       [-pedantic -Wall -Wextra],
+                       [G])
 
-AS_IF([test "x$enable_use_deprecations" = xyes],
-[
-DISABLE_DEPRECATED_CFLAGS='-DG_DISABLE_DEPRECATED'
-],[
-DISABLE_DEPRECATED_CFLAGS=
-])
-AC_SUBST([DISABLE_DEPRECATED_CFLAGS])
+# TODO: kill dummy
+AC_SUBST([DISABLE_DEPRECATED_CFLAGS], [[]])
 
 #Offer the ability to omit some API from the library, 
 #to reduce the code size:
-GLIBMM_ARG_ENABLE_API_DEPRECATED()
-GLIBMM_ARG_ENABLE_API_EXCEPTIONS()
-GLIBMM_ARG_ENABLE_API_PROPERTIES()
-GLIBMM_ARG_ENABLE_API_VFUNCS()
+GLIBMM_ARG_ENABLE_API_DEPRECATED
+GLIBMM_ARG_ENABLE_API_EXCEPTIONS
+GLIBMM_ARG_ENABLE_API_PROPERTIES
+GLIBMM_ARG_ENABLE_API_VFUNCS
 
 # Offer the ability to omit some API from the library, 
 # to reduce the code size:
-GLIBMM_ARG_ENABLE_API_DEFAULT_SIGNAL_HANDLERS()
+GLIBMM_ARG_ENABLE_API_DEFAULT_SIGNAL_HANDLERS
 
 # Dummy conditional just to make automake-1.4 happy.
 # We need an always-false condition in docs/Makefile.am.
+# TODO: kill
 AM_CONDITIONAL(GTKMM_FALSE,[false])
 
-# HACK:  Assign a dummy in order to prevent execution of autoheader by the
-# maintainer-mode rules.  That would fail since we aren't using autoheader.
-AUTOHEADER=':'
-
-
 AC_CONFIG_FILES([
   Makefile
 
@@ -374,6 +235,4 @@ AC_CONFIG_FILES([
       MSVC_Net2008/tests/glibmm_value/Makefile
       MSVC_Net2008/tests/giomm_simple/Makefile
 ])
-
-AC_OUTPUT()
-
+AC_OUTPUT



[Date Prev][Date Next]   [Thread Prev][Thread Next]   [Thread Index] [Date Index] [Author Index]