empathy r880 - in trunk: . m4 python/pyempathy python/pyempathygtk

[xclaesse svn gnome org]

Author: xclaesse
Date: Wed Apr  9 13:15:19 2008
New Revision: 880
URL: http://svn.gnome.org/viewvc/empathy?rev=880&view=rev

Log:
Empathy should not require python-config. Fixes bug #525562 (Frederic Peters).


Added:
   trunk/m4/python.m4
Modified:
   trunk/configure.ac
   trunk/python/pyempathy/Makefile.am
   trunk/python/pyempathygtk/Makefile.am

Modified: trunk/configure.ac
==============================================================================
--- trunk/configure.ac	(original)
+++ trunk/configure.ac	Wed Apr  9 13:15:19 2008
@@ -68,7 +68,7 @@
 if test -z "$XSLTPROC"; then
   AC_MSG_ERROR([xsltproc (from libxslt) is required])
 fi
-AC_CHECK_PROGS([PYTHON], [python2.3 python2.4 python2.5 python])
+AC_CHECK_PROGS([PYTHON], [python python2.3 python2.4 python2.5])
 if test -z "$PYTHON"; then
   AC_MSG_ERROR([Python is required])
 fi
@@ -268,6 +268,9 @@
          gtk+-2.0 >= $GTK_REQUIRED
          libglade-2.0 >= $LIBGLADE_REQUIRED
       ], have_python="yes", have_python="no")
+      if test "x$have_python" = "xyes" ; then
+         AM_CHECK_PYTHON_HEADERS(,have_python="no")
+      fi
    fi
 else
    have_python=no

Added: trunk/m4/python.m4
==============================================================================
--- (empty file)
+++ trunk/m4/python.m4	Wed Apr  9 13:15:19 2008
@@ -0,0 +1,66 @@
+## this one is commonly used with AM_PATH_PYTHONDIR ...
+dnl AM_CHECK_PYMOD(MODNAME [,SYMBOL [,ACTION-IF-FOUND [,ACTION-IF-NOT-FOUND]]])
+dnl Check if a module containing a given symbol is visible to python.
+AC_DEFUN([AM_CHECK_PYMOD],
+[AC_REQUIRE([AM_PATH_PYTHON])
+py_mod_var=`echo $1['_']$2 | sed 'y%./+-%__p_%'`
+AC_MSG_CHECKING(for ifelse([$2],[],,[$2 in ])python module $1)
+AC_CACHE_VAL(py_cv_mod_$py_mod_var, [
+ifelse([$2],[], [prog="
+import sys
+try:
+        import $1
+except ImportError:
+        sys.exit(1)
+except:
+        sys.exit(0)
+sys.exit(0)"], [prog="
+import $1
+$1.$2"])
+if $PYTHON -c "$prog" 1>&AC_FD_CC 2>&AC_FD_CC
+  then
+    eval "py_cv_mod_$py_mod_var=yes"
+  else
+    eval "py_cv_mod_$py_mod_var=no"
+  fi
+])
+py_val=`eval "echo \`echo '$py_cv_mod_'$py_mod_var\`"`
+if test "x$py_val" != xno; then
+  AC_MSG_RESULT(yes)
+  ifelse([$3], [],, [$3
+])dnl
+else
+  AC_MSG_RESULT(no)
+  ifelse([$4], [],, [$4
+])dnl
+fi
+])
+
+dnl a macro to check for ability to create python extensions
+dnl  AM_CHECK_PYTHON_HEADERS([ACTION-IF-POSSIBLE], [ACTION-IF-NOT-POSSIBLE])
+dnl function also defines PYTHON_INCLUDES
+AC_DEFUN([AM_CHECK_PYTHON_HEADERS],
+[AC_REQUIRE([AM_PATH_PYTHON])
+AC_MSG_CHECKING(for headers required to compile python extensions)
+dnl deduce PYTHON_INCLUDES
+py_prefix=`$PYTHON -c "import sys; print sys.prefix"`
+py_exec_prefix=`$PYTHON -c "import sys; print sys.exec_prefix"`
+if test -x "$PYTHON-config"; then
+PYTHON_INCLUDES=`$PYTHON-config --includes 2>/dev/null`
+else
+PYTHON_INCLUDES="-I${py_prefix}/include/python${PYTHON_VERSION}"
+if test "$py_prefix" != "$py_exec_prefix"; then
+  PYTHON_INCLUDES="$PYTHON_INCLUDES -I${py_exec_prefix}/include/python${PYTHON_VERSION}"
+fi
+fi
+AC_SUBST(PYTHON_INCLUDES)
+dnl check if the headers exist:
+save_CPPFLAGS="$CPPFLAGS"
+CPPFLAGS="$CPPFLAGS $PYTHON_INCLUDES"
+AC_TRY_CPP([#include <Python.h>],dnl
+[AC_MSG_RESULT(found)
+$1],dnl
+[AC_MSG_RESULT(not found)
+$2])
+CPPFLAGS="$save_CPPFLAGS"
+])

Modified: trunk/python/pyempathy/Makefile.am
==============================================================================
--- trunk/python/pyempathy/Makefile.am	(original)
+++ trunk/python/pyempathy/Makefile.am	Wed Apr  9 13:15:19 2008
@@ -6,7 +6,7 @@
 	-I$(top_srcdir)                                 \
 	-DDATADIR=\""$(datadir)"\"              	\
 	$(PYTHON_BINDING_CFLAGS)			\
-	`python-config --cflags`			\
+	$(PYTHON_INCLUDES)				\
 	$(WARN_CFLAGS)
 
 BUILT_SOURCES = 					\
@@ -24,7 +24,6 @@
 	$(top_builddir)/libempathy/libempathy.la
 
 empathy_la_LDFLAGS =					\
-	`python-config --libs`				\
 	-module -avoid-version
 
 pyempathy.c: pyempathy.override pyempathy.defs

Modified: trunk/python/pyempathygtk/Makefile.am
==============================================================================
--- trunk/python/pyempathygtk/Makefile.am	(original)
+++ trunk/python/pyempathygtk/Makefile.am	Wed Apr  9 13:15:19 2008
@@ -6,7 +6,7 @@
 	-I$(top_srcdir)                                 \
 	-DDATADIR=\""$(datadir)"\"              	\
 	$(PYTHON_BINDING_CFLAGS)			\
-	`python-config --cflags`			
+	$(PYTHON_INCLUDES)
 
 BUILT_SOURCES = 					\
 	pyempathygtk.c					
@@ -24,7 +24,6 @@
 	$(top_builddir)/libempathy-gtk/libempathy-gtk.la
 
 empathygtk_la_LDFLAGS =					\
-	`python-config --libs`				\
 	-module -avoid-version
 
 pyempathygtk.c: pyempathygtk.override pyempathygtk.defs