# $Id$
# Maintainer: Steve Holmes <steve holmes88 gmail com>
# Contributor: William Rea <sillywilly gmail com>
# Contributor: Peter Vagner <pvdeejay gmail com>

pkgname=orca-git
_gitname='orca'
pkgver=20131109.ORCA_3_9_92_98_g1892a6c
pkgrel=1
pkgdesc="Screen reader for individuals who are blind or visually impaired"
arch=(any)
license=('LGPL')
url="http://www.gnome.org/projects/orca"
install=orca-git.install
options=('!libtool')
depends=(gtk3 at-spi2-atk python-atspi python-dbus python-xdg speech-dispatcher liblouis brltty
         xorg-xmodmap hicolor-icon-theme gsettings-desktop-schemas)
makedepends=(itstool intltool gnome-doc-utils gnome-common)
groups=(gnome-extra)
provides=('orca')
conflicts=('orca')
source=("$_gitname::git://git.gnome.org/orca"
    'orca-git.install')
sha256sums=('SKIP'
    'a750e49ef56200e0c183b65ad9bffc0349203cf1f674899b4ff221b5ef9398d6')

build() {
    cd ${_gitname}
    msg "Creating build directory"
    cd ${srcdir}
    [ -d ${_gitname}-build ] && rm -rf ${_gitname}-build
    /usr/share/git/workdir/git-new-workdir ${_gitname} ${_gitname}-build master

    msg "Starting make..."
    cd ${_gitname}-build
    ./autogen.sh --prefix=/usr --sysconfdir=/etc --localstatedir=/var
    make
}

package() {
    cd "$srcdir/$_gitname-build"
    make DESTDIR="$pkgdir" install
}

pkgver() {
    cd "$srcdir/$_gitname"
    echo $(git log -1 --format="%ci" | sed 's/.*\([0-9]\{4\}\)-\([0-9]\{2\}\)-\([0-9]\{2\}\).*/\1\2\3/').$(git describe --always | tr '-' '_' )
}